Kueri untuk tabel ABSBotRequests

Untuk informasi tentang menggunakan kueri ini di portal Azure, lihat tutorial Analitik Log. Untuk REST API, lihat Kueri.

Saluran Saluran Direct Line Klien

Log Klien ke permintaan saluran Direct Line.

// All the API calls that clients make to Direct Line channel
// e.g. Generate a Token, Refresh a Token, Post an Activity, Get Activities, GetAttachments, etc.
// You can adjust the limit value to the number of logs you would like to retrieve.
ABSBotRequests
| where OperationName contains "ClientToDirectLine"
| sort by TimeGenerated desc
| limit 100

Bot Ke Saluran

Log permintaan dari Bot ke saluran.

// This shows logs of requests sent by the bot to Azure Bot Service channels.
// You can adjust the limit value to the number of logs you would like to retrieve.
ABSBotRequests
| where OperationName contains "BotToChannel"
| sort by TimeGenerated desc
| limit 100

Saluran Ke Bot

Log permintaan dari Saluran ke bot.

// This query retrieves logs of requests sent from Azure Bot Service channels to the bot.
// You can adjust the limit value to the number of logs you would like to retrieve.
ABSBotRequests
| where OperationName contains "ChannelToBot"
| sort by TimeGenerated desc
| limit 100

Permintaan Dari Facebook Ke Azure Bot Service

Log permintaan dari Facebook ke Saluran Facebook Azure Bot Service.

// To retrieve logs for another channel, replace FacebookToChannel with the respective channel request operation name 
// e.g. SlackToChannel, KikToChannel, GroupmeToChannel, LineToChannel, SMSToChannel, TelegramToChannel and EmailToChannel.
ABSBotRequests
| where OperationName contains "FacebookToChannel"
| sort by TimeGenerated desc

Permintaan Dari Azure Bot Service Ke API Facebook

Log permintaan dari Saluran Facebook Azure Bot Service ke API Facebook.

// To retrieve logs for another channel, replace ChannelToFacebookAPI with the respective channel request operation name 
// e.g. ChannelToSlackAPI, ChannelToGroupmeAPI, ChannelToKikAPI, ChannelToLineAPI, ChannelToSMSAPI, ChannelToTelegramAPI and ChannelToEmailAPI.
ABSBotRequests
| where OperationName contains "ChannelToFacebookAPI"
| sort by TimeGenerated desc

Aktivitas yang Dikirim dari Klien ke Direct Line

Log permintaan untuk mengirim aktivitas dari klien ke saluran Direct Line.

// This query displays logs of requests sent from a client such as WebChat to Direct Line channel.
// Replace 'SendAnActivity:ClientToDirectLine' with any operation name whose logs you would like to retrieve.
ABSBotRequests
| where OperationName == 'SendAnActivity:ClientToDirectLine'
| sort by TimeGenerated desc

Log Saluran Direct Line

Ambil log yang terkait dengan saluran Direct Line.

// This query retrieves logs of requests related to Direct Line channel.
ABSBotRequests
| where Channel == "directline"
| sort by TimeGenerated desc

Permintaan yang Gagal

Daftar log permintaan yang gagal.

// Retrieve all logs of requests that have not been successful within a selected time range.
ABSBotRequests
| where ResultCode < 200 or ResultCode >= 300
| sort by TimeGenerated desc

Bagan Garis Kode Respons Saluran Saluran Langsung

Bagan Garis memperlihatkan kode respons permintaan saluran Direct Line.

// This query displays a Line Chart showing requests related to Direct Line channel.
ABSBotRequests
| where Channel == "directline"
| summarize Number_Of_Requests = count() by tostring(ResultCode), bin(TimeGenerated, 5m)
| render timechart

Bagan Garis Durasi Permintaan

Bagan Garis memperlihatkan waktu/durasi respons permintaan per operasi.

// This query displays a Line Chart showing requests response duration per operation.
ABSBotRequests
| summarize DurationMs = avg(DurationMs)  by bin(TimeGenerated, 5m), OperationName
| render timechart

Bagan Garis Kode Respons

Bagan Garis memperlihatkan kode status respons permintaan.

// Display a Line Chart of requests response status codes.
ABSBotRequests
| summarize Number_Of_Requests = count() by tostring(ResultCode), bin(TimeGenerated, 5m)
| render timechart

Kode Respons PieChart

Bagan Pai memperlihatkan kode status respons permintaan.

// Display a Pie Chart showing requests response status codes.
ABSBotRequests
| summarize count() by tostring(ResultCode)      
| render piechart

Meminta Operasi PieChart

Bagan Pai memperlihatkan operasi permintaan.

// Display a Pie Chart showing requests by operation name.
// This gives a perspective of the request operations percentage distribution in the selected time range.
ABSBotRequests
| summarize count() by tostring(OperationName)      
| render piechart