Mulai cepat: Membuat instans Azure API Management menggunakan Terraform

BERLAKU UNTUK: Pengembang | Standar | Premi

Artikel ini memperlihatkan cara menggunakan Terraform untuk membuat instans API Management di Azure. Anda juga dapat menggunakan Terraform untuk tugas manajemen umum seperti mengimpor API di instans API Management Anda.

Azure API Management membantu organisasi menerbitkan API ke pengembang eksternal, mitra, dan internal untuk membuka potensi data dan layanan mereka. API Management menyediakan kompetensi inti untuk memastikan program API yang sukses melalui keterlibatan pengembang, wawasan bisnis, analitik, keamanan, dan perlindungan. Dengan API Management, buat dan kelola gateway API modern untuk layanan backend yang ada yang dihosting di mana saja.

Terraform memungkinkan definisi, pratinjau, dan penyebaran infrastruktur cloud. Menggunakan Terraform, Anda membuat file konfigurasi menggunakan sintaksis HCL. Sintaksis HCL memungkinkan Anda menentukan penyedia cloud - seperti Azure - dan elemen yang membentuk infrastruktur cloud Anda. Setelah membuat file konfigurasi, Anda membuat rencana eksekusi yang memungkinkan Anda untuk melihat pratinjau perubahan infrastruktur Anda sebelum disebarkan. Setelah memverifikasi perubahan, Anda menerapkan rencana eksekusi untuk menyebarkan infrastruktur.

Dalam artikel ini, Anda akan mempelajari cara:

Prasyarat

• Jika Anda tidak memiliki langganan Azure, buat akun gratis sebelum Anda memulai.

• Menginstal dan mengonfigurasi Terraform

• Untuk Azure CLI:

  • Gunakan lingkungan Bash di Azure Cloud Shell. Untuk informasi selengkapnya, lihat Mulai Cepat untuk Bash di Azure Cloud Shell.

    

  • Jika Anda lebih suka menjalankan perintah referensi CLI secara lokal, instal Azure CLI. Jika Anda menjalankan Windows atau macOS, pertimbangkan untuk menjalankan Azure CLI dalam kontainer Docker. Untuk informasi lebih lanjut, lihat Cara menjalankan Azure CLI di kontainer Docker.

    • Jika Anda menggunakan instalasi lokal, masuk ke Azure CLI dengan menggunakan perintah login az. Untuk menyelesaikan proses autentikasi, ikuti langkah-langkah yang ditampilkan di terminal Anda. Untuk opsi masuk lainnya, lihat Masuk dengan Azure CLI.

    • Saat Anda diminta, instal ekstensi Azure CLI pada penggunaan pertama. Untuk informasi selengkapnya tentang ekstensi, lihat Menggunakan ekstensi dengan Azure CLI.

    • Jalankan versi az untuk menemukan versi dan pustaka dependen yang diinstal. Untuk meningkatkan ke versi terbaru, jalankan peningkatan az.

• Untuk Azure PowerShell:

  • Jika Anda memilih untuk menggunakan Azure PowerShell secara lokal:
    • Instal versi terbaru modul Az PowerShell.
    • Sambungkan ke akun Azure Anda menggunakan cmdlet Connect-AzAccount.
  • Jika Anda memilih untuk menggunakan Azure Cloud Shell:
    • Lihat Gambaran Umum Azure Cloud Shell untuk informasi selengkapnya.

Menerapkan kode Terraform

1. Buat direktori untuk menguji dan menjalankan contoh kode Terraform dan menjadikannya direktori saat ini.

2. Buat file bernama main.tf dan masukkan kode berikut:

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     name     = random_pet.rg_name.id
     location = var.resource_group_location
   }
   
   resource "random_string" "azurerm_api_management_name" {
     length  = 13
     lower   = true
     numeric = false
     special = false
     upper   = false
   }
   
   resource "azurerm_api_management" "api" {
     name                = "apiservice${random_string.azurerm_api_management_name.result}"
     location            = azurerm_resource_group.rg.location
     resource_group_name = azurerm_resource_group.rg.name
     publisher_email     = var.publisher_email
     publisher_name      = var.publisher_name
     sku_name            = "${var.sku}_${var.sku_count}"
   }
   

3. Buat file bernama outputs.tf dan masukkan kode berikut:

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "api_management_service_name" {
     value = azurerm_api_management.api.name
   }
   

4. Buat file bernama providers.tf dan masukkan kode berikut:

   terraform {
     required_version = ">=1.0"
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   provider "azurerm" {
     features {}
   }
   

5. Buat file bernama variables.tf dan masukkan kode berikut:

   variable "resource_group_location" {
     type        = string
     default     = "eastus"
     description = "Location for all resources."
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     default     = "rg"
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
   }
   
   variable "publisher_email" {
     default     = "test@contoso.com"
     description = "The email address of the owner of the service"
     type        = string
     validation {
       condition     = length(var.publisher_email) > 0
       error_message = "The publisher_email must contain at least one character."
     }
   }
   
   variable "publisher_name" {
     default     = "publisher"
     description = "The name of the owner of the service"
     type        = string
     validation {
       condition     = length(var.publisher_name) > 0
       error_message = "The publisher_name must contain at least one character."
     }
   }
   
   variable "sku" {
     description = "The pricing tier of this API Management service"
     default     = "Developer"
     type        = string
     validation {
       condition     = contains(["Developer", "Standard", "Premium"], var.sku)
       error_message = "The sku must be one of the following: Developer, Standard, Premium."
     }
   }
   
   variable "sku_count" {
     description = "The instance size of this API Management service."
     default     = 1
     type        = number
     validation {
       condition     = contains([1, 2], var.sku_count)
       error_message = "The sku_count must be one of the following: 1, 2."
     }
   }
   

Inisialisasi Terraform

Jalankan terraform init untuk menginisialisasi penyebaran Terraform. Perintah ini mengunduh penyedia Azure yang diperlukan untuk mengelola sumber daya Azure Anda.

terraform init -upgrade

Poin utama:

• Parameter -upgrade meningkatkan plugin penyedia yang diperlukan ke versi terbaru yang sesuai dengan batasan versi konfigurasi.

Buat rencana eksekusi Terraform

Jalankan terraform plan untuk membuat rencana eksekusi.

terraform plan -out main.tfplan

Poin utama:

• Perintah terraform plan membuat rencana eksekusi, tetapi tidak menjalankannya. Perintah ini justru menentukan tindakan yang diperlukan untuk membuat konfigurasi yang ditentukan dalam file konfigurasi Anda. Pola ini memungkinkan Anda memastikan apakah rencana eksekusi telah sesuai dengan ekspektasi Anda sebelum membuat perubahan pada sumber daya aktual.
• Parameter -out opsional memungkinkan Anda menentukan file output untuk rencana. Menggunakan parameter -out memastikan bahwa rencana yang Anda tinjau benar-benar sesuai dengan yang diterapkan.

Terapkan rencana eksekusi Terraform

Jalankan terraform apply untuk menerapkan rencana eksekusi ke infrastruktur cloud Anda.

terraform apply main.tfplan

Poin utama:

• Contoh terraform apply perintah mengasumsikan Anda sebelumnya menjalankan terraform plan -out main.tfplan.
• Jika Anda menentukan nama file yang berbeda untuk parameter -out, gunakan nama file yang sama dalam panggilan ke terraform apply.
• Jika Anda tidak menggunakan parameter -out, panggil terraform apply tanpa parameter apa pun.

Memverifikasi hasil

Membersihkan sumber daya

Ketika Anda tidak lagi membutuhkan sumber daya yang dibuat melalui Terraform, lakukan langkah-langkah berikut:

1. Jalankan terraform plan dan tentukan bendera destroy.

   terraform plan -destroy -out main.destroy.tfplan
   

   Poin utama:

   • Perintah terraform plan membuat rencana eksekusi, tetapi tidak menjalankannya. Perintah ini justru menentukan tindakan yang diperlukan untuk membuat konfigurasi yang ditentukan dalam file konfigurasi Anda. Pola ini memungkinkan Anda memastikan apakah rencana eksekusi telah sesuai dengan ekspektasi Anda sebelum membuat perubahan pada sumber daya aktual.
   • Parameter -out opsional memungkinkan Anda menentukan file output untuk rencana. Menggunakan parameter -out memastikan bahwa rencana yang Anda tinjau benar-benar sesuai dengan yang diterapkan.

2. Jalankan terraform apply untuk menerapkan rencana eksekusi.

   terraform apply main.destroy.tfplan
   

Memecahkan masalah Terraform pada Azure

Memecahkan masalah umum saat menggunakan Terraform di Azure

Langkah berikutnya