Megosztás a következőn keresztül:

Table.TransformColumnTypes

  • Cikk

Szintaxis

Table.TransformColumnTypes(table as table, typeTransformations as list, optional culture as nullable text) as table

Körülbelül

Egy táblát ad vissza úgy, hogy az átalakítási műveleteket a megadott oszlopokra alkalmazza egy opcionális kultúra használatával.

  • table: Az átalakítandó bemeneti tábla.
  • typeTransformations: Az alkalmazandó típusátalakítások. Egyetlen átalakítás formátuma { oszlopnév, típusérték }. Az átalakítások listája egyszerre több oszlop típusának módosítására is használható. Ha egy oszlop nem létezik, hibaüzenet jelenik meg.
  • culture: (Nem kötelező) Az a kultúra, amelyet az oszloptípusok átalakításakor kell használni (például "en-US").

A typeTransformations paraméter típusértéke lehet any, az összes number típus, text, az összes date, time, datetime, datetimezoneés duration típus, logicalvagy binary. A list, record, tablevagy function típus nem érvényes erre a paraméterre.

1. példa

Az első oszlop számértékeinek átalakítása szöveges értékekké.

Használat

let
    Source = #table(type table [a = number, b = number],
    {
        {1, 2},
        {3, 4}
    }),
    #"Transform Column" = Table.TransformColumnTypes(
        Source, 
        {"a", type text}
    )
in
    #"Transform Column"

kimeneti

#table(type table [a = text, b = number],
{
    {"1", 2},
    {"3", 4}
})

2. példa

Alakítsa át a táblázat dátumait a francia szöveg megfelelőivé.

Használat

let
    Source = #table(type table [Company ID = text, Country = text, Date = date],
    {
        {"JS-464", "USA", #date(2024, 3, 24)},
        {"LT-331", "France", #date(2024, 10, 5)},
        {"XE-100", "USA", #date(2024, 5, 21)},
        {"RT-430", "Germany", #date(2024, 1,18)},
        {"LS-005", "France", #date(2023, 12, 31)},
        {"UW-220", "Germany", #date(2024, 2, 25)}
    }),
    #"Transform Column" = Table.TransformColumnTypes(
        Source,
        {"Date", type text},
        "fr-FR"
    )
in
    #"Transform Column"

kimeneti

#table(type table [Company ID = text, Country = text, Date = text],
    {
        {"JS-464", "USA", "24/03/2024"},
        {"LT-331", "France", "05/10/2024"},
        {"XE-100", "USA", "21/05/2024"},
        {"RT-430", "Germany", "18/01/2024"},
        {"LS-005", "France", "31/12/2023"},
        {"UW-220", "Germany", "25/02/2024"}
    })

3. példa

A táblázat dátumait alakítsa át a német szöveg megfelelőivé, a táblában lévő értékeket pedig százalékokra.

Használat

let
    Source = #table(type table [Date = date, Customer ID = text, Value = number],
    {
        {#date(2024, 3, 12), "134282", .24368},
        {#date(2024, 5, 30), "44343", .03556},
        {#date(2023, 12, 14), "22", .3834}
    }),
    #"Transform Columns" = Table.TransformColumnTypes(
        Source, 
        {{"Date", type text}, {"Value", Percentage.Type}},
        "de-DE") 
in
    #"Transform Columns"

kimeneti

#table(type table [Date = text, Customer ID = text, Value = Percentage.Type],
{
    {"12.03.2024", "134282", .24368},
    {"30.05.2024", "44343", .03556},
    {"14.12.2023", "22", .3834}
})

Kapcsolódó tartalom