Standard dátum- és időformátum-sztringek

A szabványos dátum- és időformátum-sztringek egyetlen karaktert használnak formátumkijelölőként az idő- és dátumértékek szöveges ábrázolásának meghatározásához. Minden olyan dátum- és időformátum-sztring, amely egynél több karaktert tartalmaz, beleértve a szóközt is, egyéni dátum- és időformátum-sztringként lesz értelmezve. Egy szabványos vagy egyéni formázási sztring használatával meghatározhatja a formázási műveletből származó szövegábrázolást.

Formátumjelölők táblázata

Az alábbi táblázat a szabványos dátum- és időformátum-meghatározókat ismerteti.

A szabványos formázási sztringek működése

A formázási műveletekben a szabványos formázási sztringek egyszerűen egy egyéni formázási sztring aliasai. Az aliasok egyéni formátumsztringekre való hivatkozásának előnye, hogy bár az alias invariáns marad, maga az egyéni formázási sztring változhat. Ez azért fontos, mert a dátum- és időértékek sztring-ábrázolása általában kultúra szerint változik. A "d" szabványos formátum sztringje például azt jelzi, hogy egy dátum- és időértéket rövid dátummintával kell megjeleníteni. Az invariáns kultúra esetében ez a minta "MM/dd/ééééé". Az fr-FR kultúra esetében ez a "dd/MM/yyyyy". A ja-JP kultúra esetében ez "yyyyy/MM/dd".

Ha egy formázási művelet szabványos formátumsztringje egy adott kulturális kultúra egyéni formátumsztringjéhez van rendelve, az alkalmazás az alábbi módokon definiálhatja azt a kulturális környezetet, amelynek egyéni formázási sztringjei vannak használva:

• Használhatja az alapértelmezett (vagy aktuális) kultúrát. Az alábbi példa egy dátumot jelenít meg az aktuális kultúra rövid dátumformátumával. Ebben az esetben a jelenlegi kultúra az EN-US.

  let
      Source =
      {
          Date.ToText(#date(2024, 3, 15), [Format = "d"])
          //Displays 3/15/2024
      }
  in
      Source
  

• Átadhat egy kultúrát, amellyel a dátumot az adott kultúra szabályai szerint formázhatja. Az alábbi példa egy dátumot jelenít meg a pt-BR-kultúra rövid dátumformátumával.

  let
      Source =
      {
          Date.ToText(#date(2024, 3, 15), [Format = "d", Culture = "pt-BR"])
          //Displays 15/03/2024
     }
  in
      Source
  

Bizonyos esetekben a standard formátumsztring kényelmes rövidítésként szolgál egy hosszabb, invariáns formátumú egyéni sztringhez. Négy szabványos formátumsztring tartozik ebbe a kategóriába: "O" (vagy "o"), "R" (vagy "r"), "s" és "u". Ezek a sztringek az invariáns kultúra által meghatározott egyéni formátumsztringeknek felelnek meg. Sztring-ábrázolásokat készítenek a különböző kultúrákban azonos dátum- és időértékekről. Az alábbi táblázat a négy szabványos dátum- és időformátum-sztringről nyújt tájékoztatást.

Standard formátumú sztringek is használhatók elemzési műveletekhez, amelyekhez egy bemeneti sztringnek pontosan meg kell felelnie az elemzési művelet egy adott mintájának a sikeresség érdekében. Számos szabványos formázási sztring több egyéni formátumsztringre van leképezve, így a dátum- és időértékek többféle formátumban is megjeleníthetők, és az elemzési művelet továbbra is sikeres.

A következő szakaszok a Dátum, a DateTime, a DateTimeZone és az Idő értékek szabványos formátumjelölőinek leírását ismertetik.

Dátumformátumok

Ez a csoport a következő formátumokat tartalmazza:

• A rövid dátum ("d") formátumjelölője
• A hosszú dátum ("D") formátumkijelölője

A rövid dátum ("d") formátumjelölője

A "d" standard formátumkijelölő egy adott kultúra által meghatározott egyéni dátumformátumot jelöl. Az invariáns kultúra által visszaadott egyéni formátumszöveg például "MM/dd/yyyyy".

Az alábbi példa a "d" formátumjelölőt használja egy dátumérték megjelenítéséhez.

let
    Source =
    {
        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = ""]),
        // Displays 04/10/2024

        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = "en-US"]),
        // Displays 4/10/2024

        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = "en-NZ"]),
        // Displays 10/4/2024

        Date.ToText(#date(2024, 4, 10), [Format = "d", Culture = "de-DE"])
        // Displays 10.4.2024
    }
in
    Source

Vissza a táblához

A hosszú dátum ("D") formátumkijelölője

A "D" standard formátumkijelölő egy egyéni dátumformátumot jelöl, amelyet egy adott kultúra határoz meg. Az invariáns kultúra egyéni formátumsztringje például "dddd, dd MMMM yyyyy".

Az alábbi példa a "D" formátumjelölőt használja egy dátum- és időérték megjelenítéséhez.

let
    Source =
    {
        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = ""]),
        // Displays Wednesday, 10 April, 2024

        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = "en-US"]),
        // Displays Wednesday, April 10, 2024

        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = "pt-BR"]),
        // Displays quarta-feira, 10 de abril de 2024

        Date.ToText(#date(2024, 4, 10), [Format = "D", Culture = "es-MX"])
        // Displays miércoles, 10 de abril de 2024
    }
in
    Source

Vissza a táblához

Dátum- és időformátumok

Ez a csoport a következő formátumokat tartalmazza:

• A teljes dátum rövid ideje ("f") formátumkijelölője
• A teljes dátum hosszú ideje ("F") formátumjelölője
• Az általános dátum rövid ideje ("g") formátumjelölője
• Az általános dátum hosszú ideje ("G") formátumjelölője
• Az oda-vissza ("O", "o") formátumválasztó
• Az RFC1123 ("R", "r") formátumjelölő
• A rendezhető ("s") formátumkijelölő
• Az univerzális rendezhető ("u") formátumkijelölő

A teljes dátum rövid ideje ("f") formátumkijelölője

Az "f" standard formátumjelölő a hosszú dátum ("D") és a rövid idő ("t") minták kombinációját jelöli, szóközzel elválasztva.

Az eredménysztringet egy adott kultúra formázási információi befolyásolják.

Az alábbi példa az "f" formátumjelölőt használja egy dátum- és időérték megjelenítéséhez.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "f", Culture = "en-US"]),
        // Displays Wednesday, April 10, 2024 6:30 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "f", Culture = "fr-FR"])
        // Displays mercredi 10 avril 2024 06:30
    }
in
    Source

Vissza a táblához

A teljes dátum hosszú ideje ("F") formátumjelölője

Az "F" standard formátumkijelölő egy egyéni dátum- és időformátumot jelöl, amelyet egy adott kultúra határoz meg. Az invariáns kultúra egyéni formátumsztringje például "dddd, dd MMMM yyyyy HH:mm:ss".

Az eredménysztringet egy adott kultúra formázási információi befolyásolják.

Az alábbi példa az "F" formátumjelölőt használja egy dátum- és időérték megjelenítéséhez.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "F", Culture = ""]),
        // Displays Wednesday, 10 April, 2024 06:30:00

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "F", Culture = "en-US"]),
        // Displays Wednesday, April 10, 2024 6:30:00 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "F", Culture = "fr-FR"])
        // Displays mercredi 10 avril 2024 06:30:00
    }
in
    Source

Vissza a táblához

Az általános dátum rövid ideje ("g") formátumjelölője

A "g" standard formátumjelölő a rövid dátum ("d") és a rövid idő ("t") minták kombinációját jelöli, szóközzel elválasztva. Az eredményül kapott szöveget egy adott kultúra formázási információi befolyásolják.

Az eredménysztringet egy adott kultúra formázási információi befolyásolják.

Az alábbi példa a "g" formátumjelölőt használja egy dátum- és időérték megjelenítéséhez.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "g", Culture = ""]),
        // Displays 04/10/2024 06:30

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "g", Culture = "en-US"]),
        // Displays 4/10/2024 6:30 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "g", Culture = "fr-BE"])
        // Displays 10-04-24 06:30
    }
in
    Source

Vissza a táblához

Az általános dátum hosszú ideje ("G") formátumjelölője

A "G" standard formátumjelölő a rövid dátum ("d") és a hosszú idő ("T") minták kombinációját jelöli, szóközzel elválasztva. Az eredményül kapott szöveget egy adott kultúra formázási információi befolyásolják.

Az eredménysztringet egy adott kultúra formázási információi befolyásolják.

Az alábbi példa a "G" formátumjelölőt használja egy dátum- és időérték megjelenítéséhez.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "G", Culture = ""]),
        // Displays 04/10/2024 06:30:00

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "G", Culture = "en-US"]),
        // Displays 4/10/2024 6:30:00 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "G", Culture = "nl-BE"])
        // Displays 10/04/2024 6:30:00
    }
in
    Source

Vissza a táblához

Az oda-vissza ("O", "o") formátumválasztó

Az "O" vagy "o" szabványformátum-meghatározó egy egyéni dátum- és időformátum-sztringet jelöl egy olyan mintával, amely megőrzi az időzóna adatait, és az ISO 8601-nek megfelelő eredménysztringet bocsát ki. A DateTimeZone-értékek esetében ez a formátumkijelölő a szöveg dátum-, idő- és időzónértékeinek megőrzésére szolgál.

Az "O" vagy az "o" szabványformátum-meghatározó a "yyyy'-'MM'-'dd'T'HH':'mm':'ss' értéknek felel meg." fffffffxxx" egyéni formázási sztring a DateTimeZone értékekhez. Ebben a szövegben az egyes karaktereket ( például kötőjeleket, kettőspontokat és "T" betűt) elválasztó idézőjelek párjai azt jelzik, hogy az egyes karakterek egy olyan literálisak, amelyeket nem lehet módosítani. Az aposztrófok nem jelennek meg a kimeneti sztringben.

Az "O" vagy az "o" szabványos formátumválasztó (és az "yyyy'-'MM'-'dd'T'HH':'mm':'ss'." fffffffxxx" egyéni formátum) kihasználja az ISO 8601 időzóna-információinak azon módjait, amelyekkel megőrizheti DateTimeZone értékeit:

• DateTimeZone.ToLocal dátum- és időértékek időzóna-összetevője az UTC-től (például +01:00, -07:00) való eltolás.

• A dátum- és időértékek DateTimeZone.ToUtc időzóna-összetevője a +00,00 értéket használja az UTC értékének megjelenítéséhez.

Mivel az "O" vagy az "o" szabványformátum-meghatározó megfelel egy nemzetközi szabványnak, a megadót használó formázási vagy elemzési művelet mindig az invariáns kultúrát és a Gergely-naptárt használja.

Az alábbi példa az "o" formátumkijelölőt használja a DateTimeZone értékek sorozatának megjelenítéséhez az Egyesült Államok csendes-óceáni időzónájában lévő rendszerben.

let
    date1 = #datetimezone(2024, 6, 15, 13, 45, 30, 0, 0),
    Source =
    {
        Text.Format("#{0} (Unspecified) --> #{1}", {date1, DateTimeZone.ToText(date1, [Format = "O"])}),
        Text.Format("#{0} (Utc) --> #{1}", {date1, DateTimeZone.ToText(DateTimeZone.ToUtc(date1), [Format = "O"])}),
        Text.Format("#{0} (Local) --> #{1}", {date1, DateTimeZone.ToText(DateTimeZone.ToLocal(date1), [Format = "O"])})
    }
in
    Source

// The example displays the following output:
//    6/15/2024 1:45:30 PM +00:00 (Unspecified) --> 2024-06-15T13:45:30.0000000+00:00
//    6/15/2024 1:45:30 PM +00:00 (Utc) --> 2024-06-15T13:45:30.0000000+00:00
//    6/15/2024 1:45:30 PM +00:00 (Local) --> 2024-06-15T08:45:30.0000000-07:00

Az alábbi példa az "o" formátumkijelölővel formázott sztringet hoz létre, majd egy dátum- és időelemző rutin meghívásával visszaállítja az eredeti dátum- és időértéket.

let
    // Round-trip a local time
    #"Origin Local Date" = DateTimeZone.ToLocal(
        #datetimezone(2024, 4, 10, 6, 30, 0, 0, 0)
    ),
    #"Local Date Text" = DateTimeZone.ToText(
        #"Origin Local Date", [Format = "o"]
    ),
    #"New Local Date" = DateTimeZone.FromText(#"Local Date Text"),
    #"Local Round Trip" = Text.Format(
        "Round-tripped #{0} Local to #{1} Local.", 
        {
            DateTimeZone.ToText(#"Origin Local Date"), 
            DateTimeZone.ToText(#"New Local Date")
        }
    ),

    // Round-trip a UTC time
    #"Origin UTC Date" = DateTimeZone.ToUtc(
        #datetimezone(2024, 4, 12, 9, 30, 0, 0, 0)
    ),
    #"UTC Date Text" = DateTimeZone.ToText(
        #"Origin UTC Date", [Format = "o"]
    ),
    #"New UTC Date" = DateTimeZone.FromText(#"UTC Date Text"),
    #"UTC Round Trip" = Text.Format(
        "Round-tripped #{0} UTC to #{1} UTC.", 
        {
            DateTimeZone.ToText(#"Origin UTC Date"), 
            DateTimeZone.ToText(#"New UTC Date")
        }
    ),

    // Round-trip an 18 hour offset time
    #"Origin Offset Date" = DateTimeZone.ToLocal(
        #datetimezone(2024, 4, 10, 6, 30, 0, 0, 0) + #duration(0, 18, 0, 0)
    ),
    #"Offset Date Text" = DateTimeZone.ToText(
        #"Origin Offset Date", [Format = "o"]
    ),
    #"New Offset Date" = DateTimeZone.FromText(#"Offset Date Text"),
    #"Offset Round Trip" = Text.Format(
        "Round-tripped #{0} to #{1}.", 
        {
            DateTimeZone.ToText(#"Origin Offset Date"), 
            DateTimeZone.ToText(#"New Offset Date")
        }
    ),

    #"Round Trip Results" = 
        {#"Local Round Trip", #"UTC Round Trip", #"Offset Round Trip"}
in
    #"Round Trip Results"

// The example displays the following output in Power Query Desktop:
//    Round-tripped 4/9/2024 11:30:00 PM -07:00 Local to 4/9/2024 11:30:00 PM -07:00 Local.
//    Round-tripped 4/12/2024 9:30:00 AM +00:00 UTC to 4/12/2024 9:30:00 AM +00:00 UTC.
//    Round-tripped 4/10/2024 5:30:00 PM -07:00 to 4/10/2024 5:30:00 PM -07:00.

// The example displays the following output in Power Query Online:
//    Round-tripped 4/10/2024 6:30:00 AM +00:00 Local to 4/10/2024 6:30:00 AM +00:00 Local.
//    Round-tripped 4/12/2024 9:30:00 AM +00:00 UTC to 4/12/2024 9:30:00 AM +00:00 UTC.
//    Round-tripped 4/11/2024 12:30:00 AM +00:00 to 4/11/2024 12:30:00 AM +00:00.

Vissza a táblához

Az RFC1123 ("R", "r") formátumjelölő

Az "R" vagy az "r" szabványos formátumkijelölő olyan egyéni dátum- és időformátum-sztringet jelöl, amelyet nem egy adott kultúra határoz meg. Ez mindig ugyanaz, függetlenül a használt kultúrától vagy a megadott formátumszolgáltatótól. Az egyéni formátumsztring a következő: "ddd, dd MMM yyyy HH":'mm':'ss 'GMT'. Ha ezt a szabványos formátumkijelölőt használja, a formázási vagy elemzési művelet mindig az invariáns kultúrát használja.

Bár az RFC 1123 szabvány koordinált univerzális időként (UTC) fejezi ki az időt, a formázási művelet nem módosítja a formázott dátum és idő értékét. Ezért a formázási művelet végrehajtása előtt meg kell hívnia a DateTimeZone.ToUtc függvénymetódust UTC-vé.

Az alábbi példa az "r" formátumkijelölőt használja az idő- és dátumértékek megjelenítéséhez az Egyesült Államok csendes-óceáni időzónájában (hét órával az UTC-hez képest).

let
    date1 = #datetimezone(2024, 4, 10, 6, 30, 0, -7, 0),
    dateOffset = DateTimeZone.ToUtc(date1),
    Source = 
    {
        DateTimeZone.ToText(date1, [Format = "r"]),
        // Displays Wed, 10 Apr 2024 13:30:00 GMT

        DateTimeZone.ToText(dateOffset, [Format = "r"])
        // Displays Wed, 10 Apr 2024 13:30:00 GMT
    }
in
    Source

Vissza a táblához

A rendezhető ("s") formátumkijelölő

Az "s" szabványos formátumkijelölő egy egyéni dátum- és időformátum-sztringet jelöl, amely egy meghatározott szabványt (ISO 8601) tükröz, és írásvédett. Ezért mindig ugyanaz, függetlenül a használt kultúrától vagy a megadott formátumszolgáltatótól. Az egyéni formátumsztring a következő: "yyyy'-'MM'-'dd'T'HH':'mm''ss". Az "s" formátumjelölő célja olyan eredménysztringek létrehozása, amelyek a dátum- és időértékek alapján növekvő vagy csökkenő sorrendben rendeznek.

Ha ezt a szabványos formátumkijelölőt használja, a formázási vagy elemzési művelet mindig az invariáns kultúrát használja.

Az alábbi példa az "s" formátumkijelölővel jeleníti meg a dátum- és időértéket egy rendszeren az Egyesült Államok csendes-óceáni időzónájában.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "s", Culture = "en-US"])
        // Displays 2024-04-10T06:30:00
    }
in
    Source

Vissza a táblához

Az univerzális rendezhető ("u") formátumkijelölő

Az "u" szabványos formátumkijelölő egy egyéni dátum- és időformátum-sztringet jelöl, amely mindig ugyanaz, függetlenül a használt kultúrától vagy a megadott formátumszolgáltatótól. Az egyéni formátumsztring a következő: "yyyy'-'MM'-'dd HH':'mm':'ss'Z'". A minta egy meghatározott szabványt tükröz, és a tulajdonság írásvédett. Ha ezt a szabványos formátumkijelölőt használja, a formázási vagy elemzési művelet mindig az invariáns kultúrát használja.

Bár az eredménysztringnek koordinált univerzális időként (UTC) kell kifejeznie az időt, a formázási művelet során nem történik meg az eredeti DateTimeZone-érték konvertálása . Ezért a formázás előtt a DateTimeZone értéket utc értékre kell konvertálnia a DateTimeZone.ToUtc függvény meghívásával.

Az alábbi példa az "u" formátumkijelölőt használja egy dátum- és időérték megjelenítéséhez.

let
    date1 = #datetimezone(2024, 4, 10, 6, 30, 0, -7, 0),
    dateOffset = DateTimeZone.ToUtc(date1),
    Source =
    {
        DateTimeZone.ToText(dateOffset, [Format = "u"]),
        // Displays 2024-04-10 13:30:00Z
    }
in
    Source

Vissza a táblához

Időformátumok

Ez a csoport a következő formátumokat tartalmazza:

• A rövid idő ("t") formátumkijelölője
• A hosszú idő ("T") formátumkijelölője

A rövid idő ("t") formátumkijelölője

A "t" szabványos formátumkijelölő egy egyéni dátum- és időformátum-sztringet jelöl, amelyet a megadott kultúra határoz meg. Az invariáns kultúra egyéni formátumsztringje például "HH:mm".

Az eredménysztringet egy adott kultúra formázási információi befolyásolják.

Az alábbi példa a "t" formátumjelölőt használja egy dátum- és időérték megjelenítéséhez.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "t", Culture = ""]),
        // Displays 06:30
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "t", Culture = "en-US"]),
        // Displays 6:30 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "t", Culture = "es-ES"])
        // Displays 6:30
    }
in
    Source

Vissza a táblához

A hosszú idő ("T") formátumkijelölője

A "T" standard formátumkijelölő egy egyéni dátum- és időformátum-sztringet jelöl, amelyet az adott kultúra határoz meg. Az invariáns kultúra egyéni formátumsztringje például "HH:mm:ss".

Az alábbi példa a "T" formátumkijelölőt használja egy dátum- és időérték megjelenítéséhez.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "T", Culture = ""]),
        // Displays 06:30:00
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "T", Culture = "en-US"]),
        // Displays 6:30:00 AM

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "T", Culture = "es-ES"])
        // Displays 6:30:00
    }
in
    Source

Vissza a táblához

Részleges dátumformátumok

Ez a csoport a következő formátumokat tartalmazza:

• A hónap ("M", "m") formátumjelölője
• Az év hónap ("Y", "y") formátumjelölője

A hónap ("M", "m") formátumjelölője

Az "M" vagy az "m" szabványos formátumkijelölő az adott kultúra által meghatározott egyéni dátum- és időformátum-sztringet jelöli. Az invariáns kultúra egyéni formátumsztringje például az "MMMM dd".

Az alábbi példa az "m" formátumjelölőt használja egy dátum- és időérték megjelenítéséhez.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "m", Culture = ""]),
        // Displays April 10
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "m", Culture = "en-US"]),
        // Displays April 10

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "m", Culture = "ms-MY"])
        // Displays 10 April
    }
in
    Source

Vissza a táblához

Az év hónap ("Y", "y") formátumjelölője

Az "Y" vagy az "y" szabványos formátumkijelölő egy egyéni dátumformátum-sztringet jelöl, amelyet egy adott kultúra határoz meg. Az invariáns kultúra egyéni formátumsztringje például az "ééé MMMM".

Az alábbi példa az "y" formátumjelölőt használja egy dátum- és időérték megjelenítéséhez.

let
    Source =
    {
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "Y", Culture = ""]),
        // Displays 2024 April
        
        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "Y", Culture = "en-US"]),
        // Displays April 2024

        DateTime.ToText(#datetime(2024, 4, 10, 6, 30, 0), [Format = "y", Culture = "af-ZA"])
        // Displays April 2024
    }
in
    Source

Vissza a táblához

Kapcsolódó tartalom

• Hogyan befolyásolja a kultúra a szövegformázást?
• Dátum, idő, datetime és DateTimeZone típusú átalakítás
• Dátumfüggvények
• DateTime függvények
• DateTimeZone függvények
• Időfüggvények
• Egyéni dátum- és időformátum-karakterláncok