Végponthoz készült Microsoft Defender üzembe helyezése Linuxon a Puppet használatával

A következőkre vonatkozik:

• Végponthoz készült Microsoft Defender Server
• Microsoft Defender kiszolgálókhoz

Szeretné megismerni a Végponthoz készült Defendert? Regisztráció az ingyenes próbaverzióra

Ez a cikk azt ismerteti, hogyan helyezheti üzembe a Végponthoz készült Defendert Linuxon a Puppet használatával.

Előfeltételek és rendszerkövetelmények

Az előfeltételek és a rendszerkövetelmények leírásáért lásd: Végponthoz készült Microsoft Defender Linuxon.

Emellett a Puppet üzembe helyezéséhez ismernie kell a Puppet felügyeleti feladatait, konfigurálnia kell a Puppetet, és ismernie kell a csomagok üzembe helyezésének módját. A Puppetnek számos módja van arra, hogy ugyanazt a feladatot elvégezze. Ezek az utasítások feltételezik a támogatott Puppet-modulok rendelkezésre állását, például az apt-t a csomag üzembe helyezéséhez. Előfordulhat, hogy a szervezet más munkafolyamatot használ. További információt a Puppet dokumentációjában talál.

Az előkészítési csomag letöltése

Töltse le az előkészítési csomagot Microsoft Defender portálról.

1. A Microsoft Defender portálon lépjen a Beállítások>Végpontok>Eszközkezelés>Előkészítés területre.

2. Az első legördülő menüben válassza a Linux Server elemet operációs rendszerként. A második legördülő menüben válassza az Előnyben részesített Linux-konfigurációkezelő eszközt telepítési módszerként.

3. Válassza az Előkészítési csomag letöltése lehetőséget. Mentse a fájlt néven WindowsDefenderATPOnboardingPackage.zip.

   

4. Bontsa ki az archívum tartalmát.

   unzip WindowsDefenderATPOnboardingPackage.zip
   

   Archive:  WindowsDefenderATPOnboardingPackage.zip
   inflating: mdatp_onboard.json
   

Címtárstruktúra létrehozása

Létre kell hoznia egy könyvtárstruktúrát a Végponthoz készült Defender Linuxon történő üzembe helyezéséhez a Puppet-kiszolgáló által felügyelt eszközökön. Ez a példa a és a modult puppetlabshasználja, aptyumrepo és feltételezi, hogy a modulok telepítve vannak a Puppet-kiszolgálón.

1. A Puppet telepítése esetén a modulok mappájában hozza létre a és install_mdatp/manifestsa mappátinstall_mdatp/files. A modulok mappája általában a Puppet-kiszolgálón található /etc/puppetlabs/code/environments/production/modules .

2. Másolja a mdatp_onboard.json korábban létrehozott fájlt a install_mdatp/files mappába.

3. Hozzon létre egy init.pp fájlt, amely tartalmazza az üzembehelyezési utasításokat:

   pwd
   

   /etc/puppetlabs/code/environments/production/modules
   

   tree install_mdatp
   

   install_mdatp
   ├── files
   │   └── mdatp_onboard.json
   └── manifests
       └── init.pp
   

Puppet-jegyzék létrehozása

A jegyzékfájl kétféleképpen hozható létre:

• Használjon telepítőszkriptet; vagy
• Konfigurálja manuálisan az adattárakat.

Jegyzékfájl létrehozása a Végponthoz készült Defender üzembe helyezéséhez telepítőszkript használatával

1. Töltse le a telepítő bash szkriptet. Kérje le a telepítő bash szkriptet a Microsoft GitHub-adattárból, vagy töltse le a következő paranccsal.

wget https://raw.githubusercontent.com/microsoft/mdatp-xplat/refs/heads/master/linux/installation/mde_installer.sh /etc/puppetlabs/code/environments/production/modules/install_mdatp/files/

2. Adja hozzá az alábbi tartalmat a install_mdatp/manifests/init.pp fájlhoz. A fájlt közvetlenül a GitHubról is letöltheti

# Puppet manifest to install Microsoft Defender for Endpoint on Linux.
# @param channel The release channel based on your environment, insider-fast or prod.

class install_mdatp (
  $channel = 'prod',
) {
  # Ensure that the directory /tmp/mde_install exists
  file { '/tmp/mde_install':
    ensure => directory,
    mode   => '0755',
  }

  # Copy the installation script to the destination
  file { '/tmp/mde_install/mde_installer.sh':
    ensure => file,
    source => 'puppet:///modules/install_mdatp/mde_installer.sh',
    mode   => '0777',
  }

  # Copy the onboarding script to the destination
  file { '/tmp/mde_install/mdatp_onboard.json':
    ensure => file,
    source => 'puppet:///modules/install_mdatp/mdatp_onboard.json',
    mode   => '0777',
  }

  # Install MDE on the host using an external script
  exec { 'install_mde':
    command     => "/tmp/mde_install/mde_installer.sh --install --channel ${channel} --onboard /tmp/mde_install/mdatp_onboard.json",
    path        => '/bin:/usr/bin',
    user        => 'root',
    logoutput   => true,
    require     => File['/tmp/mde_install/mde_installer.sh', '/tmp/mde_install/mdatp_onboard.json'], # Ensure the script is copied before running the installer
  }

}

Jegyzékfájl létrehozása a Végponthoz készült Defender üzembe helyezéséhez az adattárak manuális konfigurálásával

Adja hozzá az alábbi tartalmat a install_mdatp/manifests/init.pp fájlhoz. A GitHubról is letöltheti.

# Puppet manifest to install Microsoft Defender for Endpoint on Linux.
# @param channel The release channel based on your environment, insider-fast or prod.

class install_mdatp::configure_debian_repo (
  String $channel,
  String $distro,
  String $version ) {
  # Configure the APT repository for Debian-based systems

  $release = $channel ? {
    'prod'  => $facts['os']['distro']['codename'],
    default => $channel
    }
  
  apt::source { 'microsoftpackages':
    location => "https://packages.microsoft.com/${distro}/${version}/prod",
    release  => $release,
    repos    => 'main',
    key      => {
      'id'     => 'BC528686B50D79E339D3721CEB3E94ADBE1229CF',
      'server' => 'keyserver.ubuntu.com',
    },
  }
}

class install_mdatp::configure_redhat_repo (
  String $channel,
  String $distro,
  String $version) {
  # Configure the Yum repository for RedHat-based systems
  
  yumrepo { 'microsoftpackages':
    baseurl  => "https://packages.microsoft.com/rhel/${version}/prod",
    descr    => 'packages-microsoft-com-prod',
    enabled  => 1,
    gpgcheck => 1,
    gpgkey   => 'https://packages.microsoft.com/keys/microsoft.asc',
  }
}

class install_mdatp::install {
  # Common configurations for both Debian and RedHat
  
  file { ['/etc/opt', '/etc/opt/microsoft', '/etc/opt/microsoft/mdatp']:
    ensure  => directory,
    owner   => 'root',
    group   => 'root',
    mode    => '0755',
  }

  file { '/etc/opt/microsoft/mdatp/mdatp_onboard.json':
    source  => 'puppet:///modules/install_mdatp/mdatp_onboard.json',
    owner   => 'root',
    group   => 'root',
    mode    => '0600',
    require => File['/etc/opt/microsoft/mdatp'],
  }

  # Install mdatp package
  package { 'mdatp':
    ensure  => installed,
    require => [
      File['/etc/opt/microsoft/mdatp/mdatp_onboard.json'],
    ],
  }
}


class install_mdatp (
  $channel = 'prod'
) {
  # Include the appropriate class based on the OS family
  
  $distro = downcase($facts['os']['name'])
  $version = $facts['os']['release']['major']
  
  case $facts['os']['family'] {
    'Debian': {
      class { 'install_mdatp::configure_debian_repo':
        channel => 'prod',
        distro => $distro,
        version => $version
        } -> class { 'install_mdatp::install': }
    }
    'RedHat': {
      class { 'install_mdatp::configure_redhat_repo':
        channel => 'prod',
        distro => $distro,
        version => $version,
        } -> class { 'install_mdatp::install': }
    }
    default: { fail("${facts['os']['family']} is currently not supported.")}
  }
}

A jegyzékfájl belefoglalása a site.pp fájlba

Adja meg a cikkben korábban ismertetett jegyzékfájlt a site.pp fájlban:

cat /etc/puppetlabs/code/environments/production/manifests/site.pp

node "default" {
    include install_mdatp
}

A regisztrált ügynökeszközök rendszeres időközönként lekérdezik a Puppet Servert, és amint észlelik őket, telepítsenek új konfigurációs profilokat és szabályzatokat.

A Puppet üzembe helyezésének monitorozása

Az ügynökeszközön a következő parancs futtatásával is ellenőrizheti az üzembe helyezés állapotát:

mdatp health

...
healthy                                 : true
health_issues                           : []
licensed                                : true
org_id                                  : "[your organization identifier]"
...

• healthy: Győződjön meg arról, hogy a Végponthoz készült Defender üzembe helyezése és működtetése sikeresen megtörtént.
• health_issues: Az állapot hamissá válását okozó problémákat ismerteti.
• licensed: Megerősíti, hogy az eszköz a szervezethez van kötve.
• orgId: A Végponthoz készült Defender szervezeti azonosítója.

A telepítési problémák elhárítása

Ha a telepítés során problémákat tapasztal, próbálkozzon az alábbi önkiszolgáló hibaelhárítási lépésekkel:

1. A hiba esetén a telepítő által automatikusan létrehozott napló megkereséséről további információt a Naplótelepítési problémák című témakörben talál.

2. A gyakran előforduló telepítési problémákkal kapcsolatos további információkért tekintse meg a telepítési problémákat ismertető cikket

3. Ha az eszköz állapota hamis, tekintse meg MDE ügynök állapotával kapcsolatos problémákat

4. A termék teljesítményével kapcsolatos problémák esetén lásd: Teljesítményproblémák elhárítása, teljesítményhangolás

5. A proxyval és a kapcsolattal kapcsolatos problémákért lásd: Felhőkapcsolati problémák elhárítása

Ha támogatást szeretne kapni a Microsofttól, hozzon létre egy támogatási jegyet, és adja meg a naplófájlokat az ügyfélelemző használatával

Szabályzatok konfigurálása linuxos Microsoft Defender

A végpontokon konfigurálhatja a víruskereső és az EDR beállításait. További információért olvassa el az alábbi témaköröket:

• A linuxos Végponthoz készült Microsoft Defender beállításainak megadása ismerteti az elérhető beállításokat
• A biztonsági beállítások kezelése leírja, hogyan konfigurálhatja a beállításokat a Microsoft Defender portálon.

Operációs rendszer frissítései

Amikor az operációs rendszert egy új főverzióra frissíti, először el kell távolítania a Végponthoz készült Defendert Linuxon, telepítenie kell a frissítést, majd újra kell konfigurálnia a Végponthoz készült Defendert Linuxon az eszközön.

Eltávolítás

Hozzon létre egy ehhez hasonló install_mdatp modult remove_mdatp a fájlban a init.pp következő tartalommal:

class remove_mdatp {
    package { 'mdatp':
        ensure => 'purged',
    }
}