Rövid útmutató: Batch-fiók létrehozása Bicep-fájllal

Ismerkedés az Azure Batch-lel egy Bicep-fájl használatával Batch-fiók létrehozásához, beleértve a tárterületet is. Számítási erőforrások (számítási csomópontok készletei) és Batch-feladatok létrehozásához Batch-fiókra van szükség. Összekapcsolhat egy Azure Storage-fiókot a Batch-fiókjával, amely hasznos alkalmazások üzembe helyezéséhez, valamint a bemeneti és kimeneti adatok tárolásához a legtöbb valós számítási feladathoz.

A rövid útmutató elvégzése után megismerheti a Batch szolgáltatás alapvető fogalmait, és készen áll arra, hogy nagyobb léptékben próbálja ki a Batchet reálisabb számítási feladatokkal.

A Bicep tartományspecifikus nyelv (DSL), amely deklaratív szintaxist használ az Azure-erőforrások üzembe helyezéséhez. Tömör szintaxist és megbízható típusbiztonságot kínál, valamint biztosítja a kódok újrafelhasználhatóságát. A Bicep a legjobb szerzői élményt nyújtja az Azure-beli infrastruktúra-kódmegoldásokhoz.

Előfeltételek

Aktív Azure-előfizetéssel kell rendelkeznie.

• Ha nem rendelkezik Azure-előfizetéssel, első lépésként hozzon létre egy ingyenes Azure-fiókot.

A Bicep-fájl áttekintése

Az ebben a rövid útmutatóban használt Bicep-fájl az Azure Gyorsindítási sablonokból származik.

@description('Batch Account Name')
param batchAccountName string = '${toLower(uniqueString(resourceGroup().id))}batch'

@description('Storage Account type')
@allowed([
  'Standard_LRS'
  'Standard_GRS'
  'Standard_ZRS'
  'Premium_LRS'
])
param storageAccountsku string = 'Standard_LRS'

@description('Location for all resources.')
param location string = resourceGroup().location

var storageAccountName = '${uniqueString(resourceGroup().id)}storage'

resource storageAccount 'Microsoft.Storage/storageAccounts@2023-01-01' = {
  name: storageAccountName
  location: location
  sku: {
    name: storageAccountsku
  }
  kind: 'StorageV2'
  tags: {
    ObjectName: storageAccountName
  }
  properties: {
    minimumTlsVersion: 'TLS1_2'
    allowBlobPublicAccess: false
    networkAcls: {
      defaultAction: 'Deny'
    }
    supportsHttpsTrafficOnly: true
  }
}

resource batchAccount 'Microsoft.Batch/batchAccounts@2024-02-01' = {
  name: batchAccountName
  location: location
  tags: {
    ObjectName: batchAccountName
  }
  properties: {
    autoStorage: {
      storageAccountId: storageAccount.id
    }
  }
}

output storageAccountName string = storageAccount.name
output batchAccountName string = batchAccount.name
output location string = location
output resourceGroupName string = resourceGroup().name
output resourceId string = batchAccount.id

Két Azure-erőforrás van definiálva a Bicep-fájlban:

• Microsoft.Storage/storageAccounts: Létrehoz egy tárfiókot.
• Microsoft.Batch/batchAccounts: Létrehoz egy Batch-fiókot.

A Bicep-fájl üzembe helyezése

1. Mentse a Bicep-fájlt main.bicep néven a helyi számítógépre.

2. Telepítse a Bicep-fájlt az Azure CLI vagy az Azure PowerShell használatával.

   • Parancssori felület
   • PowerShell

   az group create --name exampleRG --location eastus
   az deployment group create --resource-group exampleRG --template-file main.bicep
   

   Amikor az üzembe helyezés befejeződött, egy üzenetnek kell megjelennie, amely jelzi, hogy az üzembe helyezés sikeres volt.

Az üzembe helyezés ellenőrzése

Az Azure Portal, az Azure CLI vagy az Azure PowerShell használatával listázhatja az erőforráscsoportban üzembe helyezett erőforrásokat.

az resource list --resource-group exampleRG

Get-AzResource -ResourceGroupName exampleRG

Az erőforrások eltávolítása

Ha további oktatóanyagokat tervez folytatni, érdemes lehet ezeket az erőforrásokat a helyén hagyni. Ha már nincs rá szükség, az Azure Portal, az Azure CLI vagy az Azure PowerShell használatával törölje az erőforráscsoportot és annak összes erőforrását.

az group delete --name exampleRG

Remove-AzResourceGroup -Name exampleRG

Következő lépések

Ebben a rövid útmutatóban létrehozott egy Batch-fiókot és egy tárfiókot a Bicep használatával. Az Azure Batchről további információt az Azure Batch-oktatóanyagokban találhat.