Rövid útmutató: Azure API Management-példány létrehozása a Terraform használatával

A KÖVETKEZŐKRE VONATKOZIK: Fejlesztő | Standard | Prémium

Ez a cikk bemutatja, hogyan hozhat létre API Management-példányt az Azure-ban a Terraform használatával. A Terraformot olyan gyakori felügyeleti feladatokhoz is használhatja, mint például api-k importálása az API Management-példányban.

Az Azure API Management segítségével a szervezetek api-kat tehetnek közzé külső, partneri és belső fejlesztőknek, hogy kiaknázhassák adataik és szolgáltatásaik lehetőségeit. Az API Management a fejlesztők bevonásán, az üzleti elemzéseken, a biztonságon és a védelmen keresztül biztosítja az alapvető kompetenciákat az API-program sikeressé tételéhez. Az API Management segítségével modern API-átjárókat hozhat létre és kezelhet a bárhol üzemeltetett meglévő háttérszolgáltatásokhoz.

A Terraform lehetővé teszi a felhőinfrastruktúra definícióját, előzetes verzióját és üzembe helyezését. A Terraform használatával konfigurációs fájlokat hozhat létre HCL-szintaxissal. A HCL szintaxissal megadhatja a felhőszolgáltatót – például az Azure-t – és a felhőinfrastruktúra elemeit. A konfigurációs fájlok létrehozása után létrehoz egy végrehajtási tervet , amely lehetővé teszi az infrastruktúra változásainak előzetes megtekintését az üzembe helyezés előtt. A módosítások ellenőrzése után alkalmazza a végrehajtási tervet az infrastruktúra üzembe helyezésére.

Ebben a cikkben az alábbiakkal ismerkedhet meg:

Előfeltételek

• Ha még nincs Azure-előfizetése, kezdés előtt hozzon létre egy ingyenes fiókot.

• A Terraform telepítése és konfigurálása

• Azure CLI esetén:

  • Használja a Bash-környezetet az Azure Cloud Shellben. További információ: A Bash rövid útmutatója az Azure Cloud Shellben.

    

  • Ha inkább helyi cli-referenciaparancsokat szeretne futtatni, telepítse az Azure CLI-t. Ha Windows vagy macOS rendszert használ, fontolja meg az Azure CLI Docker-tárolóban való futtatását. További információ: Az Azure CLI futtatása Docker-tárolóban.

    • Ha helyi telepítést használ, jelentkezzen be az Azure CLI-be az az login parancs futtatásával. A hitelesítési folyamat befejezéséhez kövesse a terminálon megjelenő lépéseket. További bejelentkezési lehetőségekért lásd : Bejelentkezés az Azure CLI-vel.

    • Amikor a rendszer kéri, először telepítse az Azure CLI-bővítményt. További információ a bővítményekről: Bővítmények használata az Azure CLI-vel.

    • Futtassa az az version parancsot a telepített verzió és a függő kódtárak megkereséséhez. A legújabb verzióra az az upgrade paranccsal frissíthet.

• Az Azure PowerShell esetén:

  • Ha az Azure PowerShell helyi használatát választja:
    • Telepítse az Az PowerShell-modul legújabb verzióját.
    • Csatlakozzon az Azure-fiókjához a Connect-AzAccount parancsmag használatával.
  • Ha az Azure Cloud Shell használata mellett dönt:
    • További információkért tekintse meg az Azure Cloud Shell áttekintését.

A Terraform-kód implementálása

1. Hozzon létre egy könyvtárat, amelyben tesztelheti és futtathatja a Terraform-mintakódot, és az aktuális könyvtárá teheti.

2. Hozzon létre egy elnevezett main.tf fájlt, és szúrja be a következő kódot:

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     name     = random_pet.rg_name.id
     location = var.resource_group_location
   }
   
   resource "random_string" "azurerm_api_management_name" {
     length  = 13
     lower   = true
     numeric = false
     special = false
     upper   = false
   }
   
   resource "azurerm_api_management" "api" {
     name                = "apiservice${random_string.azurerm_api_management_name.result}"
     location            = azurerm_resource_group.rg.location
     resource_group_name = azurerm_resource_group.rg.name
     publisher_email     = var.publisher_email
     publisher_name      = var.publisher_name
     sku_name            = "${var.sku}_${var.sku_count}"
   }
   

3. Hozzon létre egy elnevezett outputs.tf fájlt, és szúrja be a következő kódot:

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "api_management_service_name" {
     value = azurerm_api_management.api.name
   }
   

4. Hozzon létre egy elnevezett providers.tf fájlt, és szúrja be a következő kódot:

   terraform {
     required_version = ">=1.0"
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   provider "azurerm" {
     features {}
   }
   

5. Hozzon létre egy elnevezett variables.tf fájlt, és szúrja be a következő kódot:

   variable "resource_group_location" {
     type        = string
     default     = "eastus"
     description = "Location for all resources."
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     default     = "rg"
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
   }
   
   variable "publisher_email" {
     default     = "test@contoso.com"
     description = "The email address of the owner of the service"
     type        = string
     validation {
       condition     = length(var.publisher_email) > 0
       error_message = "The publisher_email must contain at least one character."
     }
   }
   
   variable "publisher_name" {
     default     = "publisher"
     description = "The name of the owner of the service"
     type        = string
     validation {
       condition     = length(var.publisher_name) > 0
       error_message = "The publisher_name must contain at least one character."
     }
   }
   
   variable "sku" {
     description = "The pricing tier of this API Management service"
     default     = "Developer"
     type        = string
     validation {
       condition     = contains(["Developer", "Standard", "Premium"], var.sku)
       error_message = "The sku must be one of the following: Developer, Standard, Premium."
     }
   }
   
   variable "sku_count" {
     description = "The instance size of this API Management service."
     default     = 1
     type        = number
     validation {
       condition     = contains([1, 2], var.sku_count)
       error_message = "The sku_count must be one of the following: 1, 2."
     }
   }
   

A Terraform inicializálása

Futtassa a Terraform init parancsot a Terraform üzembe helyezésének inicializálásához. Ez a parancs letölti az Azure-erőforrások kezeléséhez szükséges Azure-szolgáltatót.

terraform init -upgrade

Főbb pontok:

• A -upgrade paraméter frissíti a szükséges szolgáltatói beépülő modulokat a legújabb verzióra, amely megfelel a konfiguráció verziókorlátozásainak.

Terraform végrehajtási terv létrehozása

Végrehajtási terv létrehozásához futtassa a Terraform-tervet .

terraform plan -out main.tfplan

Főbb pontok:

• A terraform plan parancs létrehoz egy végrehajtási tervet, de nem hajtja végre. Ehelyett meghatározza, hogy milyen műveletek szükségesek a konfigurációs fájlokban megadott konfiguráció létrehozásához. Ez a minta lehetővé teszi annak ellenőrzését, hogy a végrehajtási terv megfelel-e az elvárásainak, mielőtt módosítanák a tényleges erőforrásokat.
• Az opcionális -out paraméter lehetővé teszi a terv kimeneti fájljának megadását. -out A paraméter használatával biztosítható, hogy a vizsgált terv pontosan az alkalmazott legyen.

Terraform végrehajtási terv alkalmazása

A terraform futtatásával alkalmazza a végrehajtási tervet a felhőinfrastruktúrára.

terraform apply main.tfplan

Főbb pontok:

• A példaparancs terraform apply feltételezi, hogy korábban futtatott terraform plan -out main.tfplan.
• Ha másik fájlnevet adott meg a -out paraméterhez, használja ugyanazt a fájlnevet a hívásban terraform apply.
• Ha nem használta a paramétert -out , hívjon terraform apply paraméterek nélkül.

Az eredmények ellenőrzése

Az erőforrások eltávolítása

Ha már nincs szüksége a Terraformon keresztül létrehozott erőforrásokra, hajtsa végre az alábbi lépéseket:

1. Futtassa a Terraform-tervet , és adja meg a jelölőt destroy .

   terraform plan -destroy -out main.destroy.tfplan
   

   Főbb pontok:

   • A terraform plan parancs létrehoz egy végrehajtási tervet, de nem hajtja végre. Ehelyett meghatározza, hogy milyen műveletek szükségesek a konfigurációs fájlokban megadott konfiguráció létrehozásához. Ez a minta lehetővé teszi annak ellenőrzését, hogy a végrehajtási terv megfelel-e az elvárásainak, mielőtt módosítanák a tényleges erőforrásokat.
   • Az opcionális -out paraméter lehetővé teszi a terv kimeneti fájljának megadását. -out A paraméter használatával biztosítható, hogy a vizsgált terv pontosan az alkalmazott legyen.

2. A végrehajtási terv alkalmazásához futtassa a terraformát .

   terraform apply main.destroy.tfplan
   

A Terraform hibaelhárítása az Azure-ban

A Terraform Azure-beli használatakor felmerülő gyakori problémák elhárítása

Következő lépések