Rövid útmutató: Azure AI-szolgáltatási erőforrás létrehozása a Terraform használatával

Ez a cikk bemutatja, hogyan hozhat létre többszolgáltatásos Azure AI-erőforrásokat a Terraform használatával a Terraform használatával.

Az Azure AI-szolgáltatások segítségével a fejlesztők és szervezetek gyorsan hozhatnak létre intelligens, élvonalbeli, piackész és felelős alkalmazásokat beépített, előre összeállított és testre szabható API-kkal és modellekkel. A példaalkalmazások közé tartozik a beszélgetések természetes nyelvi feldolgozása, a keresés, a monitorozás, a fordítás, a beszéd, a látás és a döntéshozatal.

A legtöbb Azure AI-szolgáltatás REST API-k és ügyfélkódtár-SDK-k segítségével érhető el népszerű fejlesztési nyelveken. További információkért tekintse meg az egyes szolgáltatások dokumentációját.

A Terraform lehetővé teszi a felhőinfrastruktúra definícióját, előzetes verzióját és üzembe helyezését. A Terraform használatával konfigurációs fájlokat hozhat létre HCL-szintaxissal. A HCL szintaxissal megadhatja a felhőszolgáltatót – például az Azure-t – és a felhőinfrastruktúra elemeit. A konfigurációs fájlok létrehozása után létrehoz egy végrehajtási tervet , amely lehetővé teszi az infrastruktúra változásainak előzetes megtekintését az üzembe helyezés előtt. A módosítások ellenőrzése után alkalmazza a végrehajtási tervet az infrastruktúra üzembe helyezésére.

Ebben a cikkben az alábbiakkal ismerkedhet meg:

Előfeltételek

• A Terraform telepítése és konfigurálása

A Terraform-kód implementálása

1. Hozzon létre egy könyvtárat, amelyben tesztelheti és futtathatja a Terraform-mintakódot, és az aktuális könyvtárá teheti.

2. Hozzon létre egy elnevezett main.tf fájlt, és szúrja be a következő kódot:

   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     name     = random_pet.rg_name.id
     location = var.resource_group_location
   }
   
   resource "random_string" "azurerm_cognitive_account_name" {
     length  = 13
     lower   = true
     numeric = false
     special = false
     upper   = false
   }
   
   resource "azurerm_cognitive_account" "cognitive_service" {
     name                = "CognitiveService-${random_string.azurerm_cognitive_account_name.result}"
     location            = azurerm_resource_group.rg.location
     resource_group_name = azurerm_resource_group.rg.name
     sku_name            = var.sku
     kind                = "CognitiveServices"
   }
   

3. Hozzon létre egy elnevezett outputs.tf fájlt, és szúrja be a következő kódot:

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "azurerm_cognitive_account_name" {
     value = azurerm_cognitive_account.cognitive_service.name
   }
   

4. Hozzon létre egy elnevezett providers.tf fájlt, és szúrja be a következő kódot:

   terraform {
     required_version = ">=1.0"
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>3.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   provider "azurerm" {
     features {}
   }
   

5. Hozzon létre egy elnevezett variables.tf fájlt, és szúrja be a következő kódot:

   variable "resource_group_location" {
     type        = string
     description = "Location for all resources."
     default     = "eastus"
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
     default     = "rg"
   }
   
   variable "sku" {
     type        = string
     description = "The sku name of the Azure Analysis Services server to create. Choose from: B1, B2, D1, S0, S1, S2, S3, S4, S8, S9. Some skus are region specific. See https://docs.microsoft.com/en-us/azure/analysis-services/analysis-services-overview#availability-by-region"
     default     = "S0"
   }
   

A Terraform inicializálása

Futtassa a Terraform init parancsot a Terraform üzembe helyezésének inicializálásához. Ez a parancs letölti az Azure-erőforrások kezeléséhez szükséges Azure-szolgáltatót.

terraform init -upgrade

Főbb pontok:

• A -upgrade paraméter frissíti a szükséges szolgáltatói beépülő modulokat a legújabb verzióra, amely megfelel a konfiguráció verziókorlátozásainak.

Terraform végrehajtási terv létrehozása

Végrehajtási terv létrehozásához futtassa a Terraform-tervet .

terraform plan -out main.tfplan

Főbb pontok:

• A terraform plan parancs létrehoz egy végrehajtási tervet, de nem hajtja végre. Ehelyett meghatározza, hogy milyen műveletek szükségesek a konfigurációs fájlokban megadott konfiguráció létrehozásához. Ez a minta lehetővé teszi annak ellenőrzését, hogy a végrehajtási terv megfelel-e az elvárásainak, mielőtt módosítanák a tényleges erőforrásokat.
• Az opcionális -out paraméter lehetővé teszi a terv kimeneti fájljának megadását. -out A paraméter használatával biztosítható, hogy a vizsgált terv pontosan az alkalmazott legyen.

Terraform végrehajtási terv alkalmazása

A terraform futtatásával alkalmazza a végrehajtási tervet a felhőinfrastruktúrára.

terraform apply main.tfplan

Főbb pontok:

• A példaparancs terraform apply feltételezi, hogy korábban futtatott terraform plan -out main.tfplan.
• Ha másik fájlnevet adott meg a -out paraméterhez, használja ugyanazt a fájlnevet a hívásban terraform apply.
• Ha nem használta a paramétert -out , hívjon terraform apply paraméterek nélkül.

Az eredmények ellenőrzése

Az erőforrások eltávolítása

Ha már nincs szüksége a Terraformon keresztül létrehozott erőforrásokra, hajtsa végre az alábbi lépéseket:

1. Futtassa a Terraform-tervet , és adja meg a jelölőt destroy .

   terraform plan -destroy -out main.destroy.tfplan
   

   Főbb pontok:

   • A terraform plan parancs létrehoz egy végrehajtási tervet, de nem hajtja végre. Ehelyett meghatározza, hogy milyen műveletek szükségesek a konfigurációs fájlokban megadott konfiguráció létrehozásához. Ez a minta lehetővé teszi annak ellenőrzését, hogy a végrehajtási terv megfelel-e az elvárásainak, mielőtt módosítanák a tényleges erőforrásokat.
   • Az opcionális -out paraméter lehetővé teszi a terv kimeneti fájljának megadását. -out A paraméter használatával biztosítható, hogy a vizsgált terv pontosan az alkalmazott legyen.

2. A végrehajtási terv alkalmazásához futtassa a terraformát .

   terraform apply main.destroy.tfplan
   

A Terraform hibaelhárítása az Azure-ban

A Terraform Azure-beli használatakor felmerülő gyakori problémák elhárítása

Kapcsolódó tartalom

• További információ az Azure AI-szolgáltatások erőforrásairól