Partager via

Table.TransformColumnTypes

  • Article

Syntaxe

Table.TransformColumnTypes(table as table, typeTransformations as list, optional culture as nullable text) as table

À propos

Retourne une table en appliquant les opérations de transformation aux colonnes spécifiées à l’aide d’une culture facultative.

  • table: table d’entrée à transformer.
  • typeTransformations: transformations de type à appliquer. Le format d’une transformation unique est { nom de colonne, valeur de type }. Une liste de transformations peut être utilisée pour modifier les types de plusieurs colonnes à la fois. Si une colonne n’existe pas, une erreur est générée.
  • culture: (Facultatif) Culture à utiliser lors de la transformation des types de colonnes (par exemple, «en-US»).

La valeur de type dans le paramètre typeTransformations peut être any, tous les types number, text, tous les date, time, datetime, datetimezoneet duration types, logicalou binary. Les types list, record, tableou function ne sont pas valides pour ce paramètre.

Exemple 1

Transformez les valeurs numériques de la première colonne en valeurs de texte.

Utilisation

let
    Source = #table(type table [a = number, b = number],
    {
        {1, 2},
        {3, 4}
    }),
    #"Transform Column" = Table.TransformColumnTypes(
        Source, 
        {"a", type text}
    )
in
    #"Transform Column"

Sortie

#table(type table [a = text, b = number],
{
    {"1", 2},
    {"3", 4}
})

Exemple 2

Transformez les dates du tableau en équivalents de texte français.

Utilisation

let
    Source = #table(type table [Company ID = text, Country = text, Date = date],
    {
        {"JS-464", "USA", #date(2024, 3, 24)},
        {"LT-331", "France", #date(2024, 10, 5)},
        {"XE-100", "USA", #date(2024, 5, 21)},
        {"RT-430", "Germany", #date(2024, 1,18)},
        {"LS-005", "France", #date(2023, 12, 31)},
        {"UW-220", "Germany", #date(2024, 2, 25)}
    }),
    #"Transform Column" = Table.TransformColumnTypes(
        Source,
        {"Date", type text},
        "fr-FR"
    )
in
    #"Transform Column"

Sortie

#table(type table [Company ID = text, Country = text, Date = text],
    {
        {"JS-464", "USA", "24/03/2024"},
        {"LT-331", "France", "05/10/2024"},
        {"XE-100", "USA", "21/05/2024"},
        {"RT-430", "Germany", "18/01/2024"},
        {"LS-005", "France", "31/12/2023"},
        {"UW-220", "Germany", "25/02/2024"}
    })

Exemple 3

Transformez les dates du tableau en équivalents de texte allemand et les valeurs de la table en pourcentages.

Utilisation

let
    Source = #table(type table [Date = date, Customer ID = text, Value = number],
    {
        {#date(2024, 3, 12), "134282", .24368},
        {#date(2024, 5, 30), "44343", .03556},
        {#date(2023, 12, 14), "22", .3834}
    }),
    #"Transform Columns" = Table.TransformColumnTypes(
        Source, 
        {{"Date", type text}, {"Value", Percentage.Type}},
        "de-DE") 
in
    #"Transform Columns"

Sortie

#table(type table [Date = text, Customer ID = text, Value = Percentage.Type],
{
    {"12.03.2024", "134282", .24368},
    {"30.05.2024", "44343", .03556},
    {"14.12.2023", "22", .3834}
})

Contenu connexe