Κοινή χρήση μέσω

Table.TransformColumnTypes

  • Άρθρο

Σύνταξη

Table.TransformColumnTypes(table as table, typeTransformations as list, optional culture as nullable text) as table

Περίπου

Επιστρέφει έναν πίνακα εφαρμόζοντας τις λειτουργίες μετασχηματισμού στις καθορισμένες στήλες, χρησιμοποιώντας μια προαιρετική κουλτούρα.

  • table: Ο πίνακας εισόδου για μετασχηματισμό.
  • typeTransformations: Οι μετασχηματισμοί τύπου για εφαρμογή. Η μορφή για έναν μοναδικό μετασχηματισμό είναι { όνομα στήλης, τιμή τύπου }. Μια λίστα μετασχηματισμών μπορεί να χρησιμοποιηθεί για την αλλαγή των τύπων περισσότερων από μία στηλών κάθε φορά. Εάν δεν υπάρχει στήλη, προκαλείται σφάλμα.
  • culture: (Προαιρετικό) Η κουλτούρα που θα χρησιμοποιηθεί κατά τον μετασχηματισμό των τύπων στηλών (για παράδειγμα, "en-US").

Η τιμή τύπου στην παράμετρο typeTransformations μπορεί να είναι any, όλοι οι τύποι number, text, όλοι οι date, time, datetime, datetimezoneκαι duration τύποι, logicalή binary. Οι τύποι list, record, tableή function δεν είναι έγκυροι για αυτή την παράμετρο.

Παράδειγμα 1

Μετασχηματίστε τις αριθμητικές τιμές της πρώτης στήλης σε τιμές κειμένου.

χρήσης 

let
    Source = #table(type table [a = number, b = number],
    {
        {1, 2},
        {3, 4}
    }),
    #"Transform Column" = Table.TransformColumnTypes(
        Source, 
        {"a", type text}
    )
in
    #"Transform Column"

εξόδου 

#table(type table [a = text, b = number],
{
    {"1", 2},
    {"3", 4}
})

Παράδειγμα 2

Μετασχηματίστε τις ημερομηνίες στον πίνακα σε ισοδύναμα γαλλικού κειμένου.

χρήσης 

let
    Source = #table(type table [Company ID = text, Country = text, Date = date],
    {
        {"JS-464", "USA", #date(2024, 3, 24)},
        {"LT-331", "France", #date(2024, 10, 5)},
        {"XE-100", "USA", #date(2024, 5, 21)},
        {"RT-430", "Germany", #date(2024, 1,18)},
        {"LS-005", "France", #date(2023, 12, 31)},
        {"UW-220", "Germany", #date(2024, 2, 25)}
    }),
    #"Transform Column" = Table.TransformColumnTypes(
        Source,
        {"Date", type text},
        "fr-FR"
    )
in
    #"Transform Column"

εξόδου 

#table(type table [Company ID = text, Country = text, Date = text],
    {
        {"JS-464", "USA", "24/03/2024"},
        {"LT-331", "France", "05/10/2024"},
        {"XE-100", "USA", "21/05/2024"},
        {"RT-430", "Germany", "18/01/2024"},
        {"LS-005", "France", "31/12/2023"},
        {"UW-220", "Germany", "25/02/2024"}
    })

Παράδειγμα 3

Μετασχηματίστε τις ημερομηνίες του πίνακα σε ισοδύναμα γερμανικού κειμένου και τις τιμές του πίνακα σε ποσοστά.

χρήσης 

let
    Source = #table(type table [Date = date, Customer ID = text, Value = number],
    {
        {#date(2024, 3, 12), "134282", .24368},
        {#date(2024, 5, 30), "44343", .03556},
        {#date(2023, 12, 14), "22", .3834}
    }),
    #"Transform Columns" = Table.TransformColumnTypes(
        Source, 
        {{"Date", type text}, {"Value", Percentage.Type}},
        "de-DE") 
in
    #"Transform Columns"

εξόδου 

#table(type table [Date = text, Customer ID = text, Value = Percentage.Type],
{
    {"12.03.2024", "134282", .24368},
    {"30.05.2024", "44343", .03556},
    {"14.12.2023", "22", .3834}
})

Σχετικό περιεχόμενο