WMI-Aufgaben: Computerhardware

Artikel
03/11/2025

WMI-Aufgaben für Computerhardware erhalten Informationen über das Vorhandensein, den Status oder die Eigenschaften von Hardwarekomponenten. Sie können z. B. ermitteln, ob ein Computer ein Desktop oder Laptop ist. Weitere Beispiele finden Sie im TechNet ScriptCenter unter https://www.microsoft.com/technet.

Die in diesem Thema gezeigten Skriptbeispiele erhalten nur Daten vom lokalen Computer. Weitere Informationen zur Verwendung des Skripts zum Abrufen von Daten von Remotecomputern finden Sie unter Herstellen einer Verbindung mit WMI auf einem Remotecomputer.

So führen Sie ein Skript aus

Das folgende Verfahren beschreibt, wie ein Skript ausgeführt wird.

Kopieren Sie den Code, und speichern Sie ihn in einer Datei mit der Erweiterung .vbs, z. B. filename.vbs. Stellen Sie sicher, dass der Text-Editor der Datei keine .txt Erweiterung hinzu fügt.
Öffnen Sie ein Eingabeaufforderungsfenster, und navigieren Sie zu dem Verzeichnis, in dem Sie die Datei gespeichert haben.
Geben Sie cscript filename.vbs an der Eingabeaufforderung ein.
Wenn Sie nicht auf ein Ereignisprotokoll zugreifen können, überprüfen Sie, ob Sie über eine Eingabeaufforderung mit erhöhten Rechten ausgeführt werden. Einige Ereignisprotokolle, z. B. das Sicherheitsereignisprotokoll, können durch Benutzerzugriffssteuerelemente (UAC) geschützt werden.

Anmerkung

In cscript wird standardmäßig die Ausgabe eines Skripts im Eingabeaufforderungsfenster angezeigt. Da WMI-Skripts große Mengen an Ausgabe erzeugen können, möchten Sie die Ausgabe möglicherweise an eine Datei umleiten. Geben Sie cscript filename.vbs > outfile.txt an der Eingabeaufforderung ein, um die Ausgabe des filename.vbs Skripts an outfile.txtumzuleiten.

In der folgenden Tabelle sind Skriptbeispiele aufgeführt, die zum Abrufen verschiedener Datentypen vom lokalen Computer verwendet werden können.

Wie kann ich... WMI-Klassen oder -Methoden

... bestimmen, wie viel freier Arbeitsspeicher ein Computer hat?

Verwenden Sie die Klasse Win32_OperatingSystem und die FreePhysicalMemory-Eigenschaft.

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colSettings = objWMIService.ExecQuery("Select * from Win32_OperatingSystem")
For Each objOperatingSystem in colSettings 
    Wscript.Echo "Available Physical Memory: " & objOperatingSystem.FreePhysicalMemory
Next

PowerShell
`$mem = Get-WmiObject -Class Win32_OperatingSystem "System : {0}" -f $mem.csname "Free Memory: {0}" -f $mem.FreePhysicalMemory`

... ermitteln, ob ein Computer über ein DVD-Laufwerk verfügt?

Verwenden Sie die klasse Win32_CDROMDrive, und suchen Sie in der Eigenschaft Name oder DeviceID nach der Akronym-DVD.

strComputer = "."
Set objWMIService = GetObject( "winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_CDROMDrive")
For Each objItem in colItems
    Wscript.Echo "Device ID: " & objItem.DeviceID
    Wscript.Echo "Description: " & objItem.Description
    Wscript.Echo "Name: " & objItem.Name 
Next

PowerShell
`$drives = Get-WmiObject -Class Win32_CDROMDrives $drives \| Format-Table DeviceID, Description, Name -autosize`

... ermitteln, wie viel RAM auf einem Computer installiert ist?

Verwenden Sie die Win32_ComputerSystem Klasse, und überprüfen Sie den Wert der TotalPhysicalMemory-Eigenschaft.

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colSettings = objWMIService.ExecQuery("Select * from Win32_ComputerSystem")
For Each objComputer in colSettings 
    Wscript.Echo "System Name: " & objComputer.Name
    Wscript.Echo "Total Physical Memory: " & objComputer.TotalPhysicalMemory
Next

PowerShell
`$mem = Get-WmiObject -Class Win32_ComputerSystem`

... ermitteln, ob ein Computer mehr als einen Prozessor hat?

Verwenden Sie die Win32_ComputerSystem Klasse und die Eigenschaft NumberOfProcessors.

strComputer = "."
Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colSettings = objWMIService.ExecQuery("Select * from Win32_ComputerSystem")
For Each objComputer in colSettings 
    Wscript.Echo "System Name: " & objComputer.Name
    Wscript.Echo "Number of Processors: " & objComputer.NumberOfProcessors
Next

PowerShell
`"System Name : {0}" -f $system.Name "Number of Processors: {0}" -f $system.NumberOfProcessors`

... ermitteln, ob ein Computer über einen PCMCIA-Steckplatz verfügt?

Verwenden Sie die Win32_PCMCIAController Klasse, und überprüfen Sie den Wert der eigenschaft Count. Wenn Count 0 ist, verfügt der Computer über keine PCMCIA-Steckplätze.

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_PCMCIAController")
Wscript.Echo "Number of PCMCIA slots: " & colItems.Count

PowerShell
`$Pcmcia = Get-WmiObject -Class Win32_PCMCIAController` `if (!$pcmcia.count) { "Number of PCMCIA Slots: {0}" -f 1 }else { "Number of PCMCIA Slots: {0}" -f $pcmcia.count }`

... Geräte identifizieren, die nicht funktionieren (die mit einem Ausrufezeichensymbol in Geräte-Manager) gekennzeichnet sind?

Verwenden Sie die Win32_PnPEntity Klasse, und verwenden Sie die folgende Klausel in Ihrer WQL- Abfrage. WHERE ConfigManagerErrorCode <> 0 Beachten Sie, dass dieser Code möglicherweise keine USB-Geräte erkennt, die Treiber fehlen.

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_PnPEntity WHERE ConfigManagerErrorCode <> 0")
For Each objItem in colItems
    Wscript.Echo "Class GUID: " & objItem.ClassGuid
    Wscript.Echo "Description: " & objItem.Description
    Wscript.Echo "Device ID: " & objItem.DeviceID
    Wscript.Echo "Manufacturer: " & objItem.Manufacturer
    Wscript.Echo "Name: " & objItem.Name
    Wscript.Echo "PNP Device ID: " & objItem.PNPDeviceID
    Wscript.Echo "Service: " & objItem.Service
Next

PowerShell

$baddevices = Get-WmiObject Win32_PNPEntity | where {$_.ConfigManagerErrorcode -ne 0}
" Total Bad devices: {0}" -f $baddevices.count
foreach ($device in $baddevices) {
    "Name : {0}" -f $device.name
    "Class Guid : {0}" -f $device.Classguid
    "Description : {0}" -f $device.Description
    "Device ID : {0}" -f $device.deviceid
    "Manufacturer : {0}" -f $device.manufactuer
    "PNP Devcice Id : {0}" -f $device.PNPDeviceID
    "Service Name : {0}" -f $device.service
    ""
}

... bestimmen Sie die Eigenschaften der maus, die auf dem Computer verwendet wird?

Verwenden Sie die Win32_PointingDevice Klasse. Dadurch werden die Eigenschaften aller zeigenden Geräte zurückgegeben, nicht nur Mausgeräte.

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_PointingDevice")
For Each objItem in colItems
    Wscript.Echo "Description: " & objItem.Description
    Wscript.Echo "Device ID: " & objItem.DeviceID
    Wscript.Echo "Device Interface: " & objItem.DeviceInterface
    Wscript.Echo "Double Speed Threshold: " & objItem.DoubleSpeedThreshold
    Wscript.Echo "Handedness: " & objItem.Handedness
    Wscript.Echo "Hardware Type: " & objItem.HardwareType
    Wscript.Echo "INF File Name: " & objItem.InfFileName
    Wscript.Echo "INF Section: " & objItem.InfSection
    Wscript.Echo "Manufacturer: " & objItem.Manufacturer
    Wscript.Echo "Name: " & objItem.Name
    Wscript.Echo "Number Of Buttons: " & objItem.NumberOfButtons
    Wscript.Echo "PNP Device ID: " & objItem.PNPDeviceID
    Wscript.Echo "Pointing Type: " & objItem.PointingType
    Wscript.Echo "Quad Speed Threshold: " & objItem.QuadSpeedThreshold
    Wscript.Echo "Resolution: " & objItem.Resolution
    Wscript.Echo "Sample Rate: " & objItem.SampleRate
    Wscript.Echo "Synch: " & objItem.Synch
Next

PowerShell

              
              # Mausinformationen abrufen $mouse = Get-WmiObject -Class Win32_PointingDevice

              <# Decode detalis #>
function Deviceinterface { param ($value) Switch ($value) { 0 {"Other"} 1 {"Unknown"} 3 {"Serial"} 4 {"PS/2"} 5 {"Infrarot"} 6 {"HP -HIL"} 7 {"Bus Mouse"} 8 {"ADP (Apple Desktop Bus)"} 160 {"Bus Mouse DB-9"} 161 {"Bus Mouse Micro-DIN"} 162 {"USB"} } }
function Handedness { param ($value) switch ($value) { 0 {"Unknown"} 1 {"Not Applicable"} 2 {"Right-Handed Operation"} 3 {"Left-Handed Operation"} } }
Function Pointingtype {
param ($value) Schalter ($value) { 1 {"Other"} 2 {"Unknown"} 3 {"Mouse"} 4 {"Track Ball"} 5 {"Track Point"} 6 {"Gleitkomma"} 7 {"Touchpad"} 8 {"Touchscreen"} 9 {"Maus - Optischer Sensor"} } }

              <# Details anzeigen #>
"Mouse Information on System: {0}" -f $mouse.systemname
"Description : {0}" -f $mouse.Description
"Device ID : {0}" -f $mouse.DeviceID
"Device Interface : {0}" -f (Deviceinterface($mouse.DeviceInterface))
"Double Speed Threshold : {0}" -f $mouse.DoubleSpeedThreshold
"Handedness : {0}" -f (Handedness($mouse.handedness))
"Hardware Type : {0}" -f $mouse.Hardwaretype
"INF FIle Name : {0}" -f $mouse.InfFileName
"Inf Section : {0}" -f $mouse.InfSection
"Manufacturer : {0}" -f $mouse.Manufacturer
"Name : {0}" -f $mouse.Name
"Number of buttons : {0}" -f $mouse.NumberOfButtons
"PNP Device ID : {0}" -f $mouse.PNPDeviceID
"Pointing Type : {0}" -f (Pointingtype ($mouse.PointingType))
"Quad Speed Threshold : {0}" -f $mouse.QuadSpeedThreshold
"Resolution : {0}" -f $mouse.Resolution
"Sample Rate : {0}" -f $mouse.SampleRate
"Synch : {0}" -f $mouse.Synch

... ermitteln Sie die Geschwindigkeit eines Prozessors, der auf einem Computer installiert ist?

Verwenden Sie die Win32_Processor Klasse, und überprüfen Sie den Wert der MaxClockSpeed-Eigenschaft.

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_Processor")
For Each objItem in colItems
    Wscript.Echo "Processor Id: " & objItem.ProcessorId
    Wscript.Echo "Maximum Clock Speed: " & objItem.MaxClockSpeed
Next

... bestimmen, ob ein Computer ein Turm, ein Miniturm, ein Laptop usw. ist?

Verwenden Sie die Win32_SystemEnclosure Klasse, und überprüfen Sie den Wert der ChassisType-Eigenschaft.

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colChassis = objWMIService.ExecQuery("Select * from Win32_SystemEnclosure")
For Each objChassis in colChassis
    For Each objItem in objChassis.ChassisTypes
        Wscript.Echo "Chassis Type: " & objItem
    Next
Next

PowerShell
`$processors = Get-WmiObject -Class Win32_Processor foreach ($proc in $processors) { "Processor ID: " + $proc.ProcessorID "Maximum Clock Speed: " + $proc.MaxClockSpeed }`

... die Seriennummer und das Asset-Tag eines Computers abrufen?

Verwenden Sie die Win32_SystemEnclosure Klasse und die Eigenschaften SerialNumber und SMBIOSAssetTag.

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colSMBIOS = objWMIService.ExecQuery("Select * from Win32_SystemEnclosure")
For Each objSMBIOS in colSMBIOS
    Wscript.Echo "Part Number: " & objSMBIOS.PartNumber
    Wscript.Echo "Serial Number: " & objSMBIOS.SerialNumber
    Wscript.Echo "Asset Tag: " & objSMBIOS.SMBIOSAssetTag
Next

PowerShell

$colSMBIOS = Get-WmiObject -Class Win32_SystemEnclosure

foreach ($objSMBIOS in $colSMBIOS) { "Part Number: " + $objSMBIOS.PartNumber "Serial Number: " + $objSMBIOS.SerialNumber "Asset Tag: " + $objSMBIOS.SMBIOSAssetTag }

... bestimmen, welche Art von Gerät an einen USB-Anschluss angeschlossen ist?

Verwenden Sie die Win32_USBHub Klasse, und überprüfen Sie die eigenschaft Description. Diese Eigenschaft kann einen Wert wie "Massenspeichergerät" oder "Druckunterstützung" aufweisen.

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_USBHub")
For Each objItem in colItems
    Wscript.Echo "Device ID: " & objItem.DeviceID
    Wscript.Echo "PNP Device ID: " & objItem.PNPDeviceID
    Wscript.Echo "Description: " & objItem.Description
    Wscript.Echo
Next

PowerShell
`$colItems = Get-WmiObject -Class Win32_USBHub` `foreach ($objItem in $colItems) { "Device ID: " + $objItem.DeviceID "PNP Device ID: " + $objItem.PNPDeviceID "Description: " + $objItem.Description }`

... ermitteln, wie viele Bandlaufwerke auf einem Computer installiert sind?

Verwenden Sie die Klasse Win32_TapeDrive Klasse, und verwenden Sie dann die SWbemObjectSet.Count-Methode. Wenn Count = 0, werden keine Bandlaufwerke auf dem Computer installiert.

strComputer = "."
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_TapeDrive")
Wscript.Echo "Number of tape drives: " & colItems.Count

PowerShell
`$colItems = Get-WmiObject -Class Win32_TapeDrive` `foreach ($objItem in $colItems) { "Number of Drives: " + $colItems.Count }`

Beispiele

Das PowerShell-Beispiel "Multithreaded System Asset Gathering with PowerShell" sammelt eine Fülle nützlicher Systeminformationen über WMI und Multithreading mit PowerShell.

WMI-Aufgaben für Skripts und Anwendungen
WMI C++-Anwendungsbeispiele
TechNet ScriptCenter-

Freigeben über

WMI-Aufgaben: Computerhardware

So führen Sie ein Skript aus

Beispiele

Feedback

Zusätzliche Ressourcen

Freigeben über

WMI-Aufgaben: Computerhardware

So führen Sie ein Skript aus

Beispiele

Verwandte Themen

Feedback

Zusätzliche Ressourcen