ALLSELECTED

gælder for:beregnet kolonneberegnet tabelberegning af målingvisualisering

Fjerner kontekstfiltre fra kolonner og rækker i den aktuelle forespørgsel, samtidig med at alle andre kontekstfiltre eller eksplicitte filtre bevares.

Funktionen ALLSELECTED henter den kontekst, der repræsenterer alle rækker og kolonner i forespørgslen, samtidig med at eksplicitte filtre og kontekster bevares ud over række- og kolonnefiltre. Denne funktion kan bruges til at hente visuelle totaler i forespørgsler.

Syntaks

ALLSELECTED([<tableName> | <columnName>[, <columnName>[, <columnName>[,…]]]] )

Parametre

Returværdi

Konteksten for forespørgslen uden nogen kolonne- og rækkefiltre.

Bemærkninger

• Hvis der er ét argument, er argumentet enten tableName eller columnName. Hvis der er mere end ét argument, skal de være kolonner fra den samme tabel.

• Denne funktion adskiller sig fra ALL(), fordi den bevarer alle filtre, der udtrykkeligt er angivet i forespørgslen, og den bevarer alle andre kontekstfiltre end række- og kolonnefiltre.

• Denne funktion understøttes ikke til brug i DirectQuery-tilstand, når den bruges i beregnede kolonner eller RLS-regler (row-level security).

Eksempel

I følgende eksempel kan du se, hvordan du genererer forskellige niveauer af visuelle totaler i en tabelrapport ved hjælp af DAX udtryk. I rapporten er der anvendt to (2) tidligere filtre på forhandlersalgsdataene. den ene på Sales Territory Group = Europe og den anden på Promotion Type = Volume Discount. Når der er anvendt filtre, kan visuelle totaler beregnes for hele rapporten, for Alle år eller for Alle produktkategorier. Til illustrationsformål hentes hovedtotalen for Alle forhandlersalg også, så alle filtre i rapporten fjernes. Evaluering af følgende DAX udtryk resulterer i en tabel med alle de oplysninger, der er nødvendige for at oprette en tabel med Visual Totals.

define
measure 'Reseller Sales'[Reseller Sales Amount]=sum('Reseller Sales'[Sales Amount])
measure 'Reseller Sales'[Reseller Grand Total]=calculate(sum('Reseller Sales'[Sales Amount]), ALL('Reseller Sales'))
measure 'Reseller Sales'[Reseller Visual Total]=calculate(sum('Reseller Sales'[Sales Amount]), ALLSELECTED())
measure 'Reseller Sales'[Reseller Visual Total for All of Calendar Year]=calculate(sum('Reseller Sales'[Sales Amount]), ALLSELECTED('Date'[Calendar Year]))
measure 'Reseller Sales'[Reseller Visual Total for All of Product Category Name]=calculate(sum('Reseller Sales'[Sales Amount]), ALLSELECTED('Product Category'[Product Category Name]))
evaluate
CalculateTable(
    //CT table expression
    summarize(
//summarize table expression
crossjoin(distinct('Product Category'[Product Category Name]), distinct('Date'[Calendar Year]))
//First Group by expression
, 'Product Category'[Product Category Name]
//Second Group by expression
, 'Date'[Calendar Year]
//Summary expressions
, "Reseller Sales Amount", [Reseller Sales Amount]
, "Reseller Grand Total", [Reseller Grand Total]
, "Reseller Visual Total", [Reseller Visual Total]
, "Reseller Visual Total for All of Calendar Year", [Reseller Visual Total for All of Calendar Year]
, "Reseller Visual Total for All of Product Category Name", [Reseller Visual Total for All of Product Category Name]
)
//CT filters
, 'Sales Territory'[Sales Territory Group]="Europe", 'Promotion'[Promotion Type]="Volume Discount"
)
order by [Product Category Name], [Calendar Year]

Når du har udført ovenstående udtryk i SQL Server Management Studio mod AdventureWorks DW-tabelmodellen, får du følgende resultater:

Kolonnerne i rapporten er:

Reseller Sales Amount Den faktiske værdi af Reseller Sales for året og produktkategorien. Denne værdi vises i en celle midt i rapporten ved skæringspunktet mellem år og catering.

Reseller Visual Total for All of Calendar Year Den samlede værdi for en produktkategori på tværs af alle år. Denne værdi vises i slutningen af en kolonne eller række for en given produktkategori og på tværs af alle år i rapporten.

Reseller Visual Total for All of Product Category Name Den samlede værdi for et år på tværs af alle produktkategorier. Denne værdi vises i slutningen af en kolonne eller række for et givet år og på tværs af alle produktkategorier i rapporten.

Reseller Visual Total Den samlede værdi for alle år og produktkategorier. Denne værdi vises normalt i nederste højre hjørne af tabellen.

Reseller Grand Total Dette er hovedtotalen for alt forhandlersalg, før der er anvendt et filter. Du bør bemærke forskellen med [Reseller Visual Total]. Du kan huske, at denne rapport indeholder to (2) filtre, én på Produktkategorigruppe og den anden i Kampagnetype.