Телеметрични събития за действия и синхронизиране на мобилно приложение

Power Apps Данните за мобилни приложения, свързани със събития за офлайн синхронизация, са налични за приложения, управлявани от модели и платно. Тези данни могат да се използват за оценка на изправността и производителността на събитията за офлайн синхронизиране за вашата организация.

Тези данни влизат в таблицата за Power Apps>синхронизиране и действия на мобилното приложение Application Insights. Запис се регистрира, когато потребителят осъществи достъп до мобилно Power Apps приложение, което е конфигурирано за офлайн режим. Повече данни, свързани със събития на неуспех в приложения, управлявани от модел, са достъпни чрез Power Apps>UCI.

За допълнителни примери за заявки и примерно табло посетете Примерно табло за телеметрия за използване на офлайн профил на мобилно приложение Field Service.

Синхронизиране на мобилни приложения и дефиниции на събития за действие

• id: Идентификатор на събитието.
• target: Име на сценария, проследяван от събитието.
• тип: Изходна таблица на събитието.
• name: Име на сценария, проследяван от събитието.
• продължителност: Продължителност на сценария в милисекунди. Продължителността може да включва дълги периоди от време, когато приложението е неактивно.
• operation_Id: Уникален идентификатор за сесията.
• operation_ParentId: Уникален идентификатор за сценария, проследяван от събитието.
• user_Id: Microsoft Entra потребителски идентификатор.
• application_Version: Версия на приложението.
• customDimensions: Съдържа следните атрибути:
  • "EventName": Резюме на сценария, проследяван от събитието (ScenarioEnd).
  • "ScenarioResult": УСПЕХ или ПРОВАЛ.
  • ErrorCode: Код за грешка, генериран при неуспешно синхронизиране. Научете повече в таблицата за съпоставяне на кодове за грешки.
  • ErrorMessage: Празнен при успех или низ, описващ грешката.
  • FailureType: Определя типа на неуспешното синхронизиране.
  • LogLevel: Сериозността или нивото на отчитане на събитието. Валидните стойности са информация, грешка, предупреждение, грешка или многословни.
  • DataSyncMode: Какъв тип офлайн синхронизация е изпитал потребителят.
    • DELTA_SYNC: Автоматично постепенно синхронизиране.
    • GRID_SYNC: Задейства се от опресняване на изглед на мрежа.
    • FIRST_SYNC: Първоначално синхронизиране на устройство (или след излизане/преконфигуриране).
    • FORCED_SYNC: Задейства се от бутона на страницата Състояние на устройството.
    • SINGLE_RECORD_SYNC: Задейства се от Push известие.
  • AppFlavor: Собствено приложение, инсталирано на устройствата. Валидни стойности са FieldService и PowerApps.
  • AppInfo_Version: Версията на родното приложение, както се вижда в магазина за приложения.
  • ActiveDuration: Продължителността на сценария в милисекунди, включително само времето, докато приложението е активно.
  • DeviceInfo_Id: Уникален идентификатор на устройството.
  • DeviceInfo_model: Модел на устройството (като iPhone 13).
  • DeviceInfo_make: Марка на устройството (например Apple).
  • DeviceInfo_OsName: Операционна система на устройството (като например Android).
  • DeviceInfo_OsVersion: Версия на операционната система (например Android 13).
  • Loc_country: Произход на телеметричното устройство.
  • eventContext: Съдържа следните свойства:
    • CurrentSyncId: ИД на успешен пропуск за синхронизиране. Нулиране след всяко успешно синхронизиране. (Не се нулира след грешка.)
    • CurrentActivityId: ИД на пропуска за синхронизиране. Нулиране след всяко синхронизиране.
    • entityName: Име на таблицата в събитията за изтегляне на данни.
    • ProfileId: ИД на офлайн профила, конфигуриран за приложението и потребителя.
    • RecordCount: Брой изтеглени записи.
    • ResponseSize: Размер на данните за входящия полезен товар, докладван от HTTPClient (компресиран размер).
    • ContentLength: Размерът на данните за входящия полезен товар, отчетен от HTTPClient (компресиран размер).

Събития за грешка на Унифициран клиентски интерфейс

• времеви печат [UTC]: Кога се е случило събитието.
• problemId: "uci_trace" или "uciMonitorFailure" (Откъде идват данните.)
• type: "uci_trace" или "uciMonitorFailure" (Откъде идват данните.)
• outType: "uci_trace" или "uciMonitorFailure" (Откъде идват данните.)
• outerMessage: Съобщение за грешка.
• itemType: "изключение"
• Персонализирани размери:
  • eventContext: Повече подробности, свързани с грешката.
  • ServerConnectivityState: Потребителят в офлайн режим ли е? (Офлайн/Онлайн)
  • NetworkConnectivityState: Потребителят има ли интернет връзка? Имайте предвид, че потребителят може да бъде в офлайн режим, но да има интернет връзка.
  • IsOfflineByDefaultApp: Когато е невярно, това означава, че функцията за работа в офлайн режим е включена. Когато е вярно, това означава , че офлайн първо е включено.
  • callStack: Програмният код, където е възникнала грешката.
  • hostSubType: "PowerApps-Играч-iOS-полево обслужване"
  • hostType: "MobileApplication"
• Operation_ID: Конкатенация на низ на sessionID, последвана от "_" и идентификатор на външна корелация, например, e11e8465-bc8f-4319-b64a-9c1e42453148_0da90a33-ad68-4a4e-bd45-5728d5da719a.
• Operation_ParentID: ИД на дейността, свързана с грешка.
• SessionId: ИД на сесия за грешка.
• UserId: ИД на потребител на Dynamics 365.
• User_authenticatedID: ИД на потребител на Dynamics 365.
• Application_version: Версия на приложението, например, 9.2.24045.00212.
• Client_Type: Версия на операционната система, като например iOS или Android.

Примерни сценарии

Грешки при офлайн синхронизиране по код на грешка

Тази заявка ви позволява да видите какви типове грешки срещат служителите от първа линия, когато синхронизирането е неуспешно. Някои грешки са изключени, като например ако мобилното приложение е затворено по време на синхронизиране или ако мрежата прекъсне връзката по време на синхронизиране и пречи на синхронизирането да завърши. Дефиницията на кодовете за грешки е показана в таблицата Съпоставяне на кодове за грешки.

dependencies
| where name == "Offline.SyncDatabase"
| where success == false
| extend cd = parse_json(customDimensions)
| extend AppVersion = tostring(cd.AppInfo_Version)
| extend ErrorCode = tostring(cd.ErrorCode)
| extend ErrorMessage = tostring(cd.ErrorMessage)
| extend FailureType = tostring(cd.FailureType)
| summarize dcount(user_Id), count() by ErrorCode, ErrorMessage, FailureType, bin(timestamp, 1d)

Средни записи, синхронизирани по таблица

Тази заявка ви позволява да оцените кои таблици допринасят за най-много записи за синхронизиране. Използвайки тези данни, можете да опитате допълнително да оптимизирате офлайн профила си, за да намалите записите или данните във всяка таблица.

dependencies
| where name endswith_cs "Offline.DdsClient.GetRecords"
| extend cd = parse_json(customDimensions)
| extend ec = parse_json(tostring(cd.eventContext))
| extend RecordCount = toint(ec.RecordCount)
| extend EntityName = tostring(ec.EntityName)
| extend syncid = tostring(ec.CurrentSyncId)
| extend DataSyncMode = tostring(cd.DataSyncMode)
//| where DataSyncMode == "FIRST_SYNC" //This is used to pivot on the type of sync being executed.
| summarize sum(RecordCount) by syncid, EntityName, DataSyncMode, user_Id
| summarize percentile(sum_RecordCount, 50), arg_max(sum_RecordCount, user_Id), count() by EntityName, DataSyncMode

Средна продължителност на синхронизирането чрез режим на синхронизиране

Тази заявка ви позволява да оцените средната продължителност на синхронизиране за потребителите във вашата организация.

dependencies
| where name == "Offline.SyncDatabase"
| extend cd = parse_json(customDimensions)
| extend ActiveDuration = toint(tostring(cd.ActiveDuration))
| extend WithBackgroundTime = duration
| extend DataSyncMode = tostring(cd.DataSyncMode)
| summarize percentile(ActiveDuration, 50), percentile(WithBackgroundTime, 50) by client_Type, DataSyncMode

Синхронизиране на подробности по потребител

Тази заявка предоставя изглед на синхронизацията за всеки потребител, включително дата на последно синхронизиране, последна грешка, продължителност на синхронизиране и синхронизирани записи.

dependencies
| where name == "Offline.SyncDatabase"
| extend cd = parse_json(customDimensions)
| extend ActiveDuration = toint(tostring(cd.ActiveDuration))
| extend WithBackgroundTime = duration
| extend DataSyncMode = tostring(cd.DataSyncMode)
| extend ErrorMessage = tostring(cd.ErrorMessage)
| summarize percentile(ActiveDuration, 50), percentile(WithBackgroundTime, 50), arg_max(timestamp, ErrorMessage), countif(success == false) by user_Id, DataSyncMode

Потребители по тип устройство и версия на приложението

Тази заявка дава повече информация за потребителите във вашата организация, които имат достъп до мобилното приложение на своя модел устройство.

dependencies
| where name == "Offline.SyncDatabase"
| extend cd = parse_json(customDimensions)
| extend AppVersion = tostring(cd.AppInfo_Version)
| summarize dcount(user_Id) by AppVersion, client_Type

Съпоставяне на код за грешка