استعلامات لجدول VIIndexing

للحصول على معلومات حول استخدام هذه الاستعلامات في مدخل Microsoft Azure، راجع البرنامج التعليمي Log Analytics. للحصول على واجهة برمجة تطبيقات REST، راجع الاستعلام.

عمليات الفهرسة الفاشلة

عرض سجلات حساب مفهرس الفيديو لجميع عمليات الفهرسة الفاشلة.

// Failed Indexing operations 
// Display Video Indexer Account logs of all failed indexing operations. 
VIIndexing
// | where AccountId == "<AccountId>"  // to filter on a specific accountId, uncomment this line
| where Status == "Failure"
| summarize count() by bin(TimeGenerated, 1d)
| render columnchart

أفضل 10 مستخدمين

تلخيص أفضل 10 مستخدمين.

// Video Indexer top 10 users by operations 
// Render timechart of top 10 users by operations, with an optional account id for filtering. 
// Trend of top 10 active Upn's
VIIndexing
// | where AccountId == "<AccountId>"  // to filter on a specific accountId, uncomment this line
| where OperationName in ("IndexingStarted", "ReindexingStarted")
| summarize count() by Upn
| top 10 by count_ desc
| project Upn
| join (VIIndexing
| where TimeGenerated > ago(30d)
| where OperationName in ("IndexingStarted", "ReindexingStarted")
| summarize count() by Upn, bin(TimeGenerated,1d)) on Upn
| project TimeGenerated, Upn, count_
| render timechart