استعلامات لجدول LAQueryLogs

للحصول على معلومات حول استخدام هذه الاستعلامات في مدخل Microsoft Azure، راجع البرنامج التعليمي Log Analytics. للحصول على واجهة برمجة تطبيقات REST، راجع الاستعلام.

معظم معرفات الموارد المطلوبة

معظم الموارد التي تم الاستعلام عنها على مدار ال 24 ساعة الماضية.

LAQueryLogs
| extend reqContext = parse_json(RequestContext)
| extend datasources = array_concat(reqContext["resources"], reqContext["workspaces"], reqContext["applications"])
| mv-expand datasources
| summarize reqCount = count() by tostring(datasources)
| order by reqCount desc

المستخدمون غير المصرح لهم

احصل على قائمة بالمستخدمين غير المصرح لهم بعدد طلباتهم في آخر 24 ساعة.

LAQueryLogs
| where ResponseCode == "403"
| summarize reqCount = count() by AADObjectId
| order by reqCount desc

المستخدمون المقيدون

احصل على قائمة بالمستخدمين المقيدين مع عدد طلباتهم في آخر 24 ساعة.

LAQueryLogs
| where ResponseCode == "429"
| summarize reqCount = count() by AADObjectId
| order by reqCount desc

عدد الطلبات حسب رمز الاستجابة

عدد الطلبات حسب رمز الاستجابة في غضون دقيقة واحدة من المستودعات في آخر ساعة واحدة.

LAQueryLogs
| where TimeGenerated > ago(1h)
| summarize count() by tostring(ResponseCode), bin(TimeGenerated, 1m)
| render columnchart with (kind=stacked)

أهم 10 استعلامات كثيفة الموارد

احصل على أفضل 10 استعلامات ذات وحدات البايت للمورد (استنادا إلى استهلاك وحدة المعالجة المركزية) في آخر 24 ساعة.

LAQueryLogs
| top 10 by StatsCPUTimeMs desc nulls last 

أهم 10 استعلامات للنطاق الزمني الأطول

احصل على أفضل 10 استعلامات تفحص أطول نطاق زمني في آخر 24 ساعة.

LAQueryLogs
| extend DataProcessedTimeRange = format_timespan(StatsDataProcessedEnd - StatsDataProcessedStart, 'dd.hh:mm:ss:FF')
| top 10 by DataProcessedTimeRange desc nulls last